Как да премествам автоматично имейлите с конкретни получатели на CC в Outlook

В действителност, повечето от вас може би се надяват да създадат правило в Outlook за автоматично преместване на имейли с конкретни получатели на копия. Но правилото в Outlook не поддържа проверка на получателите на копия. Така че тази статия ще ви научи как да го реализирате с Outlook VBA.

Очевидно е невъзможно за вас да създадете правило на Outlook за търсене в конкретни получатели на CC. Както е показано на следващата екранна снимка, за получените имейли можете само да проверите дали вашето собствено име е в полето CC. По същия начин за изпратените имейли дори няма условие за правило, което да постави отметка в квадратчето CC.

Следователно, ако искате да конфигурирате Outlook за автоматично преместване на имейлите с конкретни получатели на CC, трябва да потърсите други средства. Тогава. тук ще ви научим как да го постигнете чрез Outlook VBA.

Автоматично преместване на изпратените имейли с конкретни получатели на CC

1. Първо, обърнете се към раздела „Разработчик“ и кликнете върху бутона „Visual Basic“.
2. След това отворете проекта “ThisOutlookSession” и копирайте следните VBA кодове в него.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Впоследствие трябва да продължите да подписвате този код и да промените настройките на макроса както обикновено.
4. И накрая, можете да излезете от прозореца „Visual Basic“. След това имейлите с конкретните получатели на CC ще бъдат преместени в указаната пощенска папка.

Автоматично преместване на получените имейли с конкретни получатели на CC

Сега, когато горният код на VBA е насочен към преместване на изпратени имейли с конкретни получатели на CC, ако искате да търсите конкретни получатели на CC в получените имейли и след това да го преместите, вместо това трябва да използвате следните кодове.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Дръжте добре подготвени за корупцията в Outlook

Въпреки че Outlook е богат на функции, той все още не може да бъде имунизиран срещу корупция. Така че трябва да сте нащрек срещу всички потенциални рискове. Несъмнено критичната стъпка трябва да бъде създаването на последователно и актуално архивиране на данни на Outlook. Освен това трябва да запазите a корумпиран инструмент за възстановяване на Outlook в близост. Ще бъде полезен, ако и архивите, и Scanpst.exe се провалят.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително ремонт SQL Server грешка в mdf файл и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com