Windows Qovluğundakı Son Dəyişdirilmiş Faylı Outlook E-poçtunuza Necə Tez Qoşmaq olar

Bəzən müəyyən Windows qovluğunda son dəyişdirilmiş faylı tez tapmaq və Outlook e-poçtuna əlavə etmək istəyə bilərsiniz. Bu vəziyyətdə, bu məqalədə təqdim olunan metoddan istifadə edə bilərsiniz.

Bəzi istifadəçilər Outlook-a Windows qovluğunda sonuncu dəyişdirilmiş faylı tez tapıb e-poçta əlavə etmək imkanı vermək istəyir, məsələn, most yaxınlarda yaradılmış, dəyişdirilmiş və ya saxlanılan fayl. Bununla belə, Outlook belə birbaşa və yerli xüsusiyyət təklif etmir. Buna görə də, aşağıda, asanlıqla həyata keçirə bilən VBA kodunun bir parçasını ifşa edəcəyik.

Windows Qovluğundakı Son Dəyişdirilmiş Faylı E-poçta əlavə edin

1. Ən başlanğıcda Outlook proqramınızı işə salmalısınız.
2. Sonra, əsas Outlook pəncərəsinə daxil olduqdan sonra "Alt + F11" düymələrini basa bilərsiniz.
3. Sonra müvəffəqiyyətlə Outlook VBA redaktoru pəncərəsinə daxil olacaqsınız.
4. Sonradan istifadə olunmayan modulu tapıb açmalısınız.
5. Və sonra aşağıdakı VBA kodunu bu modul pəncərəsinə kopyalayıb yapışdırın.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Bundan sonra, cari VBA redaktoru pəncərəsindən çıxa və yeni makronu Tez Giriş Alətlər Panelinə və ya Mesaj pəncərəsinin lentinə əlavə etməyə davam edə bilərsiniz.
7. Daha sonra Outlook makro təhlükəsizlik səviyyənizi aşağı səviyyəyə dəyişdirməlisiniz.
8. Nəhayət, bir cəhd edə bilərsiniz.

• Birincisi, həmişəki kimi yeni Outlook e-poçtu yaradın və yaradın.
• Sonra aşağıdakı şəkildəki kimi Tez Giriş Alətlər Panelində makro düyməsini vurun:
• Sonra mənbə Windows qovluğunu seçmək və "OK" düyməsini basmağınız tələb olunacaq.
• Seçilmiş Windows qovluğunda belə bir fayl varsa, aşağıdakı ekran görüntüsünə bənzər bir sorğu alacaqsınız:
• “Bəli” düyməsini vurduğunuzda bu fayl dərhal əlavə olunacaq.

Outlook problemlərini mümkün qədər tez həll edin

Hər hansı bir Outlook problemi ilə qarşılaşdığınız zaman, onları mümkün qədər tez həll etmək tövsiyə olunur. Bu vəziyyətdə, daha yaxşı bir möhkəm hazırlamalısınız Outlook düzəlişi kimi əvvəlcədən alət DataNumen Outlook Repair. O, PST səhvlərini düzəltməyə və Outlook məlumatlarınızı effektiv şəkildə xilas etməyə qadirdir.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com