如何防止将电子邮件发送到 Outlook 中的特定电子邮件地址

许多用户希望在 Outlook 中阻止意外向特定电子邮件地址发送电子邮件。 因此，在本文中，我们将介绍一种实现它的方法。

Outlook 本身并不提供阻止向特定电子邮件地址发送邮件的功能。因此，如果您想要实现此功能，则需要编写一些脚本。接下来，我们将分享一段 VBA 代码。如果您不了解如何使用 VBA，可以阅读之前的文章——“如何在 Outlook 中运行 VBA 代码“。

防止向特定电子邮件地址发送电子邮件

1. 首先，通过“Alt + F11”访问 Outlook VBA 编辑器。
2. 然后，将以下代码放入“ThisOutlookSession”项目中。

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. 之后，退出“Microsoft Visual Basic for Applications”窗口。
4. 最终，通过以下步骤进行尝试。

• 首先，撰写电子邮件并填写收件人。
• 然后，单击“发送”按钮。
• 宏将立即展开收件人中的联系人组（如果有）并查明收件人是否包含特定的电子邮件地址。
• 如果找到该地址，您将收到一条消息，如下图所示。
• 如果您选择“否”，该特定电子邮件地址将立即被删除。
• 邮件发出后，可以查看收件人，肯定没有具体的邮件地址。

修复损坏的 Outlook 文件

你的 Outlook 文件是否曾经损坏过？这无疑是 Outlook 中最令人恼火的问题之一。遇到这种情况时，你不得不进行一些操作。 PST修复，这有点棘手。 像往常一样，您会在第一时间考虑使用 Scanpst。 但是，不幸的是，在这种情况下它可能会失败。 你的度假村应该是一个更有经验的工具，比如 DataNumen Outlook Repair，或专业的 PST 恢复服务。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 sql修复 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com