如何通过 VBA 设置联系人正文、约会和任务的默认字体

Outlook 没有为联系人正文、约会和任务项设置默认字体的本机功能。 因此，如果要指定字体，可以使用本文介绍的方法。

和邮件一样，Outlook约会、任务、联系人也有正文字段，我们可以在里面填写项目的详细信息。 但是，Outlook 只允许用户设置电子邮件正文中使用的默认字体。 如果您想在联系人、约会或任务的正文中指定字体，则必须寻求其他方法，例如第三方加载项或 Outlook VBA。 下面我们就来详细教大家如何用VBA来搞定。 继续阅读以了解详细步骤和相应的 VBA 代码。

为约会、任务和联系人的正文设置默认字体

1. 首先，启动 Outlook 程序。
2. 然后按“Alt + F11”键按钮启动 Outlook VBA 编辑器。
3. 在弹出窗口中，您需要打开“ThisOutlookSession”项目。
4. 随后，将以下 VBA 代码复制到该项目窗口中。

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objInspector As Outlook.Inspector

Public Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Public Sub objInspectors_NewInspector(ByVal Inspector As Outlook.Inspector)
    Set objInspector = Inspector
End Sub

Public Sub objInspector_Activate()
    Dim objCurrentItem As Object
    Dim objCurrentInspector As Outlook.Inspector
    Dim objWordDocument As Word.Document
    Dim objWordSelection As Word.Selection
 
    Set objCurrentItem = objInspector.CurrentItem
    Set objCurrentInspector = objCurrentItem.GetInspector
    Set objWordDocument = objCurrentInspector.WordEditor
    Set objWordSelection = objWordDocument.Application.Selection
 
    'You change the font as per your preference
    Select Case objCurrentItem.Class
           Case olContact
                With objWordSelection.Font
                     .Name = "Segoe Script"
                     .ColorIndex = wdRed
                     .Size = 8
                     .Bold = True
                End With
           Case olAppointment
                With objWordSelection.Font
                     .Name = "Comic Sans MS"
                     .ColorIndex = wdBlue
                     .Size = 9
                     .Bold = False
                End With
           Case olTask
                With objWordSelection.Font
                     .Name = "MV Boli"
                     .ColorIndex = wdGreen
                     .Size = 10
                     .Bold = True
                End With
   End Select
End Sub

5. 之后，您需要签署此代码。

• 首先，通过Digital Certificates for VBA Projects 创建一个数字证书。
• 然后将此证书分配给新的宏。

6. 稍后，您可以更改 Outlook 宏设置以允许数字签名的宏。
7. 最后，启动 Outlook 以激活新的 VBA 项目。从现在开始，当您创建新的联系人、约会或任务时，正文将使用默认字体，如下图所示：

保护您的 PST 数据免受损坏

由于 Outlook PST 文件容易出错和损坏，因此您必须非常注意 PST 保护。 例如，您应该提防来自未知来源的电子邮件，因为它们可能是带有病毒的恶意电子邮件。 一旦您的 PST 文件被感染，您必须重新使用信誉良好且经过充分验证的修复工具，例如 DataNumen Outlook Repair，这可以 修复PST 轻而易举地归档。

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 固定 SQL Server 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com