如何在 Outlook 中将周末约会自动标记为私人约会

展望解决方案 2025 年 9 月 29 日

对于大多数用户来说，周末安排的约会通常是私人的。因此，他们希望 Outlook 能自动将这类约会标记为私人约会并显示为私人约会。本文将通过编写一些脚本来实现这一功能。

为了更容易地区分商务约会和私人约会，Outlook 允许用户将约会标记为私人约会。这样，您会发现打印日历非常方便，无需私人预约。在这种情况下，您可能希望 Outlook 自动识别特定约会并将其标记为私人约会。例如，一般来说，周末的约会是私人的，因此你想让 Outlook 自动将它们标记为私人的。下面，我们将指导您实现它。

自动将周末约会标记为私人

首先，根据“启动Outlook VBA编辑器如何在 Outlook 中运行 VBA 代码“。
然后，在“Microsoft Visual Basic for Applications”窗口中，将以下代码放入“ThisOutlookSession”项目中。

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

之后，重启 Outlook 以激活宏。
从现在开始，每当您创建新约会或将现有约会更改为周末时，Outlook 都会自动将其标记为私人。

解决烦人的 Outlook 问题

您可能在处理 Outlook 时遇到了一些问题，例如应用程序意外冻结、弹出错误消息等。当他们受苦时，你会担心。请冷静下来！恐慌无济于事，只会让情况变得更糟。首先，您可以检查是否可以像往常一样访问 PST 文件。如果是这样，您必须修复 PST 文件，这可以通过收件箱维修工具或者更强大的外部工具，比如 DataNumen Outlook Repair.

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括中密度纤维板修复和 outlook 修复软件产品。欲了解更多信息，请访问 datanumen.com