如何在特定日期后自动删除来自特定发件人的 Outlook 电子邮件

立即分享:

要让您的 Outlook 自动删除特定日期特定发件人的电子邮件,您可以阅读这篇文章。 下面我们将向您展示使用VBA代码获取它的详细步骤。

提到自动删除邮件,您可能首先想到的是“自动存档”功能。 但是,它无法在自动存档电子邮件时过滤特定的发件人。 因此,例如,如果您想在 x 天后自动删除来自特定发件人的电子邮件,您应该使用其他方法,例如以下方法。

X 天后自动删除来自特定发件人的电子邮件

  1. 首先,启动 Outlook 应用程序。
  2. 然后,根据“触发Outlook VBA编辑器如何在 Outlook 中运行 VBA 代码“。
  3. 接下来,将以下 VBA 代码复制到“ThisOutlookSession”项目中。
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

VBA 代码 - 在特定日期后自动删除来自特定发件人的电子邮件

  1. 之后,重启 Outlook 以激活此宏。
  2. 从那时起,每次来自特定发件人的新电子邮件到达收件箱时,都会为其分配一个特定的到期时间——即收到后的特定天数。自动添加到期时间
  3. 然后,每次启动 Outlook 时,Outlook 都会自动检查并删除来自特定发件人的过期邮件。自动删除来自特定发件人的过期电子邮件

损坏后恢复 Outlook 数据

也许您在 Outlook 中遇到过各种错误和麻烦。 那么,您遇到过 Outlook 损坏吗? 例如,如果您经常不正确地退出 Outlook,您的 PST 文件往往会损坏。 通常,在这种情况下,您可以选择从备份中检索 Outlook 数据。 或者你可以使用 收件箱维修工具 或可靠的外部工具,例如 DataNumen Outlook Repair.

作者简介:

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.,它是数据恢复技术领域的世界领先者,包括 恢复sql 和 outlook 修复软件产品。 欲了解更多信息,请访问 datanumen.com

立即分享:

评论被关闭。