如何使用 Outlook VBA 自动使用不同的字体颜色来回复和转发电子邮件

展望解决方案 2025 年 9 月 29 日

默认情况下，您不能让 Outlook 自动使用不同的字体颜色来回复和转发电子邮件。因此，如果您有这样的需求，可以阅读这篇文章ost 学习聪明的方法。

Outlook 只允许您指定用于回复和转发电子邮件的字体。您可以转到“文件”>“选项”。然后，在“Outlook 选项”中，转到“邮件”选项卡并单击“信纸和字体...”按钮。在随后的窗口中，您可以在“回复或转发消息”中看到“字体”按钮。单击它，然后您可以为回复和转发电子邮件设置特定的字体颜色。

然而，许多用户希望在回复或转发邮件时使用不同的字体颜色。虽然 Outlook 没有为此提供任何直接功能，但它仍然可以通过 VBA 代码实现。现在，继续阅读以获得这样一段 VBA 代码。

自动使用不同的字体颜色回复和转发邮件

对于作为tart、启动 Outlook 应用程序。
然后，参考“触发VBA编辑器如何在 Outlook 中运行 VBA 代码“。
接下来，根据“如何添加对象库rary VBA 中的引用“，添加对“MS Word Object Library”。
随后，将以下代码复制到“ThisOutlookSession”项目中。

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

之后，restart Outlook 以激活此宏。
最后，你可以试试看。

选择或打开电子邮件。
然后，单击“回复”按钮。在回复电子邮件时，您可以在正文中输入一些单词。字体颜色必须是粉红色。
或者点击“全部回复”按钮。在新的“回复所有”邮件中，在正文中输入单词。字体颜色肯定是绿色的。
同样，点击“前进”按钮。在转发邮件中，新词会以蓝色显示。

求助于可靠的软件

在的情况下前景腐败，Most 用户倾向于求助于 Outlook 恢复软件。市场上有大量此类程序。其中一些甚至是免费的。然而，你应该提防那些来源不明的人，因为他们可能会使当前的情况变得越来越糟。您应该借助可靠且经验丰富的工具，例如 DataNumen Outlook Repair.

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括损坏的sql 和 outlook 修复软件产品。欲了解更多信息，请访问 datanumen.com