如何自动打开来自特定发件人的传入 Outlook 电子邮件的附件

如果您希望 Outlook 自动打开来自特定发件人的传入电子邮件的附件，您可以阅读这篇文章。 在这里，我们将指导您如何实现它。

例如，您的老板经常通过电子邮件向您发送几个重要的文件附件。 为了尽快给你的老板做出反应，你需要在收到附件时打开附件。 在这种情况下，您可能渴望有一种更智能的方法让 Outlook 自动打开您老板发来的电子邮件附件。 现在，我们将向您展示这样一种方法。

自动打开来自特定发件人的传入电子邮件的附件

1. 首先，启动 Outlook 应用程序。
2. 然后，通过快捷方式访问 VBA 编辑器 - “Alt + F11”
3. 接下来，将以下 VBA 代码放入“ThisOutlookSession”项目中。

Private Declare Function GetShortPathName Lib "kernel32" _
 Alias "GetShortPathNameA" (ByVal lpszLongPath As String, _
 ByVal lpszShortPath As String, ByVal cchBuffer As Long) As Long

Private WithEvents objItems As Outlook.Items

Private Sub Application_Startup()
    Set objItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new item arrives in Inbox
Private Sub objItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objWsShell As Object
    Dim strTempFolder As String
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Attachment
    Dim strFileName As String
 
    If Item.Class = olMail Then
       Set objMail = Item
       'Change sender email address
       If objMail.SenderEmailAddress = "boss@datanumen.com" Then
          Set objWShell = CreateObject("WScript.Shell")
          strTempFolder = Environ("Temp") & "\"
 
          Set objWsShell = CreateObject("WScript.Shell")
          Set objAttachments = objMail.Attachments
          If objAttachments.Count > 0 Then
             For Each objAttachment In objAttachments
                 strFileName = objAttachment.DisplayName
                 On Error Resume Next
                 Kill strTempFolder & strFileName
                 On Error GoTo 0
 
                 'Save the attachment
                 objAttachment.SaveAsFile strTempFolder & strFileName
 
                 'Open the attachment
                 strFileName = GetShortFileName(strTempFolder & strFileName)
                 On Error Resume Next
                 objWsShell.Run strFileName
             Next
          End If
        End If
    End If
End Sub

Function GetShortFileName(ByVal FullPath As String) As String
    Dim lAns As Long
    Dim sAns As String
    Dim iLen As Integer
 
    On Error Resume Next

    If Dir(FullPath) <> "" Then
       sAns = Space(255)
       lAns = GetShortPathName(FullPath, sAns, 255)
       GetShortFileName = Left(sAns, lAns)
    End If
End Function

4. 随后，关闭 VBA 编辑器。
5. 最后，重启 Outlook 应用程序以激活新宏。
6. 从现在开始，每当来自特定发件人的新邮件到达您的收件箱时，Outlook 将自动打开该邮件中的附件。

应用收件箱修复工具

当您的 Outlook 数据文件损坏时，您会怎么做？ 实际上，首先，您可以使用内置的 Outlook 修复工具 – 扫描仪. 它能够解决与您的 Outlook 相关的一些小问题。 如果此实用程序失败，则该是求助于更有经验和可靠的外部工具的时候了，例如 DataNumen Outlook Repair.

作者简介：

Shirley Zhang 是一位数据恢复专家 DataNumen, Inc.，它是数据恢复技术领域的世界领先者，包括 损坏的中密度纤维板 和 outlook 修复软件产品。 欲了解更多信息，请访问 datanumen.com