Agar siz a ning maxsus slaydlarini chiqarmoqchi bo'lsangiz PowerPoint taqdimotni alohida yangi taqdimotga qo'shing va uni Outlook elektron pochtasiga qo'shing, siz ushbu maqolada baham ko'rilgan usuldan foydalanishingiz mumkin.
Bir butunni biriktirish o'rniga PowerPoint taqdimotni elektron pochtaga yuborish, agar siz taqdimotning maxsus slaydlarini biriktirmoqchi bo'lsangiz, umuman olganda, avvalo, yangi taqdimotga maxsus slaydlarni nusxalashingiz kerak. Bu juda muammoli. Shuning uchun, bu erda biz sizga buni bir marta amalga oshirish mumkin bo'lgan usulni ko'rsatamiz.
a ning maxsus slaydlarini biriktiring PowerPoint Elektron pochtaga taqdimot
- Avvalo, maxsus narsani oching PowerPoint Taqdimot.
- Keyin, ichida PowerPoint dastur oynasida VBA muharririga kirish uchun “Alt + F11” tugmalarini bosing.
- Keyin, yangi oynada "Qo'shish"> "Modul" tugmasini bosib yangi modul yarating.
- Keyinchalik, ushbu modulga quyidagi VBA kodini nusxa ko'chiring va joylashtiring.
Sub AttachSpecificSlidesToOutlookEmail()
Dim objActivePresetation As Presentation
Dim objSlide As Slide
Dim n As Long
Dim strName As String
Dim strTempPresetation As String
Dim objTempPresetation As Presentation
Dim objOutlookApp As Object
Dim objMail As Object
Set objActivePresetation = ActivePresentation
For Each objSlide In objActivePresetation.Slides
objSlide.Tags.Delete ("Selected")
Next
'Add a tag "Selected" to the selected slides
For n = 1 To ActiveWindow.Selection.SlideRange.Count
ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
Next n
strName = objActivePresetation.Name
strName = Left(strName, InStrRev(strName, ".") - 1)
strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
'Copy the active presentation to a temp presentation
objActivePresetation.SaveCopyAs strTempPresetation
Set objTempPresetation = Presentations.Open(strTempPresetation)
'Remove the untagged slides
For n = objTempPresetation.Slides.Count To 1 Step -1
If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
objTempPresetation.Slides(n).Delete
End If
Next n
objTempPresetation.Save
objTempPresetation.Close
'Attach the temp presentation to a new email
Set objOutlookApp = CreateObject("Outlook.Application")
Set objMail = objOutlookApp.CreateItem(olMailItem)
'Change the email details as per your needs
With objMail
.To = "test@datanumen.com"
.Subject = strName
.Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
.Attachments.Add strTempPresetation
.Display
End With
End Sub
- Shundan so'ng siz joriy oynani yopishingiz mumkin.
- Keyinchalik, Tez kirish asboblar paneliga yangi makrosni qo'shish uchun "Fayl" > "Tanlovlar" > "Tez kirish asboblar paneli" ga o'ting.
- Nihoyat, siz ushbu makroni sinab ko'rishingiz mumkin.
- Boshlash uchun, ajratib olmoqchi bo'lgan aniq slaydlarni tanlang.
- Keyin, Tez kirish asboblar panelidagi makros tugmasini bosing.
- Bir vaqtning o'zida Outlook elektron pochta xabari paydo bo'ladi, unda a bor PowerPoint manba taqdimotidan olingan taqdimot.
Samarali tiklash vositasidan foydalaning
Barchamizga ma'lumki, Outlook o'rnatilgan ta'mirlash yordam dasturiga ega - Scanpst. Shunga qaramay, u Outlook-dagi kichik nosozliklarni oddiygina engishi mumkin. Agar siz duch kelgan narsa jiddiy zarar bo'lsa, u ta'sir qilmaydi. O'sha paytda sizda boshqa kuchli va ishonchli ta'mirlash vositasiga murojaat qilishdan boshqa tanlovingiz yo'q DataNumen Outlook Repair. Uning yordamida siz buzilgan Outlook faylingizni qutqarish imkoniyatiga ega bo'lasiz.
Muallif kirish:
Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc buzilgan mdf va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com