Outlook faylingizning papka tuzilishini Excelga qanday eksport qilish mumkin

Agar siz Outlook ma'lumotlar faylingizning papka tuzilishini Excel ish kitobiga tezda eksport qilmoqchi bo'lsangiz, ushbu maqolada keltirilgan usuldan foydalanishingiz mumkin.

Ba'zi sabablarga ko'ra, masalan, joriy Outlook papkalari va pastki papkalarini jurnalga kiritish, ko'p foydalanuvchilar Outlook faylining papka tuzilishini Excel ish kitobi kabi tashqi faylga eksport qilishni umid qilishadi. Quyida biz sizga VBA kodining bir qismini baham ko'ramiz, bu sizga bir zumda erishishingizga yordam beradi.

Outlook faylingizning papka tuzilishini Excelga eksport qiling

1. Boshlash uchun Outlook ilovangizni ishga tushiring.
2. Keyin, asosiy Outlook oynasida "Alt + F11" tugmachalarini bosing.
3. Keyinchalik, Outlook VBA muharririga kirasiz, unda siz foydalanilmagan modulni ochishingiz kerak.
4. Keyinchalik, ushbu modulga quyidagi VBA kodini nusxalashingiz mumkin.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Shundan so'ng, Outlook-da makroslar yoqilganligiga ishonch hosil qilishingiz kerak.
6. Oxir-oqibat, siz suratga olishingiz mumkin:

• Joriy makros oynasida F5 tugmachasini bosing.
• Makros tugagandan so'ng, siz "Bajarildi" degan ogohlantirish olasiz.
• Keyinchalik, yangi Excel faylini topish uchun oldindan belgilangan mahalliy papkaga o'tishingiz mumkin. Uni oching va u quyidagi skrinshotga o'xshaydi:

Hech qachon Outlook xatolariga e'tibor bermang

Imkoniyatlarning ko'pligiga qaramay, Outlook boshqa elektron pochta mijozlari kabi xatolar va buzilishlarga moyil. Shuning uchun, Outlook-dagi barcha xatolarga ahamiyat berishingiz kerak. Ularni mensimang, iltimos. Aks holda, to'plangan xatolar nihoyat Outlookning buzilishiga olib kelishi mumkin. Agar tugunli xatolarga duch kelsangiz, kuchli vositadan foydalanish tavsiya etiladi, masalan DataNumen Outlook Repairmumkin Outlook-ni ta'mirlash soniyalar ichida xatolar.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sqlni tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com