Outlook-da javob berishda asl elektron pochta qo'shimchalarini saqlashning 6 usuli

Ko'pgina foydalanuvchilar elektron pochtaga javob berishda asl elektron pochta qo'shimchalarini saqlab qolish uchun Outlook-ni sozlashni umid qilishadi. Ushbu maqolada 5 ta vaqtinchalik yechim va uni avtomatik ravishda amalga oshirish uchun VBA-dan foydalanadigan aqlli usul ko'rsatiladi.

Ko'p sonli foydalanuvchilar Outlook-da elektron pochtaga javob berishda asl qo'shimchalarni saqlash uchun mahalliy xususiyat yo'qligidan shikoyat qilishlarini eshitdim. Shuning uchun, biz bu erda sizga 6 ta usulni aytib beramiz, ulardan biri juda foydali, chunki u Outlook-ni avtomatik ravishda elektron pochtaga asl qo'shimchalarni biriktirish uchun VBA-dan foydalanadi. Endi ularni batafsil ko'rib chiqish uchun o'qing.

1. Asl elektron pochta ilovasi bilan javob bering

Outlook elektron pochtaga javob berishda asl elektron pochta qo'shimchalarini saqlash xususiyatini ta'minlamasa ham, u foydalanuvchilarga asl elektron pochtani biriktirilgan holda saqlashga imkon beradi. Shunday qilib, bu siz uchun ixtiyoriy vaqtinchalik echimdir. Javob sozlamalarini o‘zgartirish uchun “Fayl” > “Tanlovlar” > “Pochta” > “Javoblar va yo‘naltirish” bo‘limiga o‘tishingiz mumkin. Batafsil ma'lumot uchun mening oldingi maqolamga murojaat qilishingiz tavsiya etiladi - "Outlook-da asl qo'shimchalar bilan javob berish uchun 5 qadam”. Ammo, agar siz hali ham asl qo'shimchalarni saqlashga umid qilsangiz, boshqa vositalarni o'rganishga o'ting.

2. Qo'shimchalarni qo'lda sudrab olib tashlash

1. Boshlash uchun, bunday manba elektron pochtasini alohida oynada ochish uchun uni ikki marta bosing.
2. Keyin "Javob berish" tugmasini bosing, bunda javob xati paydo bo'ladi.
3. Keyin ikkala xabar oynasini bitta ekranda ko'rmaguningizcha qisqartirishingiz kerak.
4. Shundan so'ng, asl elektron pochtadagi barcha qo'shimchalarni tanlang.
5. Nihoyat, ularni javob xatidagi “Biriktirilgan” qatoriga sudrab olib boring.

3. Qo'shimchalarni qo'lda nusxalash va joylashtirish

1. Birinchi navbatda, manba elektron pochtani ochgandan so'ng, barcha qo'shimchalarni tanlang.
2. Keyin "Qo'shimchalar" yorlig'i ostidagi "Nusxalash" tugmasini bosing.
3. Shundan so'ng, javob xatini ochish uchun "Xabar" yorlig'i ostidagi "Javob berish" tugmasini bosing.
4. Oxir-oqibat, javob xatida "Biriktirilgan" qatoriga bosing va ilgari nusxalangan qo'shimchalarni joylashtirish uchun "Ctrl + V" tugmasini bosing.

4. Elektron pochtani yo'naltiring va oluvchini to'ldiring

1. Birinchidan, bunday elektron pochtani tanlang va keyin lentadagi "O'tkazish" tugmasini bosing.
2. Yangi ochilgan xabar oynasida asl qo'shimchalar saqlanadi. Endi siz asl elektron pochta jo'natuvchisiga "Kimga" maydonini to'ldirishingiz kerak.
3. Ixtiyoriy ravishda, mavzuni ehtiyojlaringizga qarab o'zgartirishingiz mumkin.

5. Ushbu elektron pochta xabarini qayta yuboring va qabul qiluvchilarni o'zgartiring

1. Boshlash uchun manba elektron pochta manzilini oching.
2. Keyin "Ko'chirish" guruhidagi "Amallar" tugmasini bosing.
3. Keyin ochiladigan ro'yxatda "Ushbu xabarni qayta yuborish" -ni tanlang.
4. Ehtimol, siz asl jo'natuvchi emasligingiz haqida ogohlantirish olasiz. Bunga e'tibor bermang va "Ha" tugmasini bosing.
5. Keyingi yangi elektron pochta xabarida "Kimga" maydonini asl elektron pochta xabarini jo'natuvchiga o'zgartirishingiz kerak.
6. Shuningdek, elektron pochta hisob qaydnomasi yordamida yuborishni o'z hisobingizga o'zgartirishni unutmang.

6. VBA orqali original qo'shimchalarni avtomatik qo'shish

Rostini aytganda, yuqorida aytib o'tilgan barcha yondashuvlar vaqtinchalik echimdir. Agar Outlook avtomatik ravishda javob berishda asl qo'shimchalarni saqlab qolishi mumkinligiga umid qilsangiz, shu usuldan foydalanishingiz mumkin.

1. Asosiy Outlook oynasida "Alt + F11" tugmalarini bosing.
2. Keyin, "Ilovalar uchun Microsoft Visual Basic" oynasida quyidagi VBA kodini "ThisOutlookSession" loyihasiga nusxalang.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Keyinroq ushbu makrosni imzolang va imzolangan makroslarga ruxsat berish uchun Outlook makro sozlamalarini o'zgartiring.
4. Shundan so'ng, ushbu VBA loyihasini faollashtirish uchun Outlook ilovangizni qayta ishga tushiring.
5. Bundan buyon har safar “Javob berish” tugmasini bosganingizda. Javob xati bir vaqtning o'zida asl qo'shimchalar bilan ko'rsatiladi.

Eng yaxshi ta'mirlash vositasiga murojaat qiling

O'zining son-sanoqsiz xususiyatlari tufayli Outlook boshqa elektron pochta mijozlaridan ustun keldi. Ammo u hali ham korruptsiyaga moyil. Shuning uchun siz uning sog'lig'iga ko'proq e'tibor berishingiz kerak. Umuman olganda, kichik muammolarga duch kelganingizda, siz shunchaki o'rnatilgan tuzatish yordam dasturiga murojaat qilishingiz mumkin. Shunday bo'lsa-da, agar siz jiddiy muammolarga duch kelsangiz, yanada malakali vositaga murojaat qilganingiz ma'qul. DataNumen Outlook Repair. U qila oladi Outlook-ni tuzatish bir zumda fayl.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sql tuzatish va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com