Як швидко видалити повторювані елементи Outlook у папці через VBA

Якщо ви хочете видалити дублікати елементів в Outlook, пошук та видалення одного за одним буде досить проблематичним. Ця публікація навчить вас, як швидко це зробити за допомогою Outlook VBA.

У моїй попередній статті - “Як швидко знайти та видалити повторювані електронні листи в Outlook”, Ви можете навчитися трюку для пошуку та видалення дублікатів електронних листів, які спочатку сортують електронні листи за темою, потім за отриманим часом, а потім за вкладеннями, щоб виявити повторювані елементи і, нарешті, виберіть повторювані та натисніть клавішу„ Видалити ”. Хоча, здається, цей метод трохи зручніший, але він набагато складніший у порівнянні з використанням Outlook VBA. За допомогою наведених нижче кодів VBA ви можете швидко видалити повторювані елементи одним клацанням миші, незалежно від електронної пошти, завдань, контактів або зустрічей. Тепер читайте далі, щоб отримати коди детально.

Видаліть повторювані елементи Outlook у папці

1. Для початку запустіть програму Outlook.
2. Потім натисніть клавіші “Alt + F11”.
3. У наступному вікні редактора VBA двічі клацніть, щоб відкрити модуль, який використовується, або безпосередньо вставити новий модуль за допомогою «Вставка»> «Модуль».
4. Далі скопіюйте та вставте наступні коди VBA в модуль.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Після цього цифрово підпишіть цей макрос і змініть рівень захисту макроса Outlook на низький.
6. Пізніше ви зможете запустити цей новий проект VBA. Клацніть безпосередньо на піктограмі "Виконати" на панелі інструментів.
7. Згодом вам потрібно буде вибрати папку, куди ви хочете видалити повторювані елементи.
8. Нарешті, повторювані елементи у вибраній папці будуть видалені відразу.

Захистіть вразливі дані PST

Через те, що файл PST сприйнятливий до корупції, вам слід витратити багато зусиль, щоб захистити свій файл PST. Наприклад, слід запобігти неправильному закриттю Outlook. Крім того, вам потрібно підготувати надійний Виправлення в Outlook інструмент, такий як DataNumen Outlook Repair що зможе вчасно врятувати ваш PST.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі оговтуватися SQL Server та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com