Як швидко роздрукувати всі вкладення зображень електронної пошти Outlook лише на одній сторінці

З метою економії чорнила та паперу на принтері деякі користувачі хочуть надрукувати всі зображення, вкладені в електронному листі, лише на одній сторінці, замість одного зображення на сторінці. Тепер ця стаття поділиться засобами для її реалізації.

Як ми всі знаємо, друк зображень досить марно витрачає чорнило принтера. Таким чином, щоб заощадити чорнило та папір на принтері, можливо, ви віддаєте перевагу друкувати багато вкладених зображень на одній сторінці, а не друкувати зображення на окремих сторінках. Хоча Outlook не пропонує таку функцію, ви все одно можете досягти її наступними способами.

Друк усіх вкладень із зображеннями електронної пошти Outlook лише на одній сторінці

1. Для початку запустіть програму Outlook.
2. Потім у вікні Outlook натисніть на кнопки “Alt + F11”.
3. Далі ви потрапите у вікно «Microsoft Visual Basic for Applications», у якому вам спочатку потрібно ввімкнути «Бібліотеку об’єктів Microsoft Word».
4. Після цього потрібно відкрити модуль, який не використовується.
5. Згодом скопіюйте та вставте наступний код VBA в цей модуль.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Пізніше ви зможете повернутися до списку розсилки. Виберіть або відкрийте електронне повідомлення, вкладене зображення якого ви хочете роздрукувати.
7. Потім активуйте цей макрос. У поточному вікні макросу просто натисніть клавішу “F5” або клацніть піктограму “Виконати” на панелі інструментів.
8. Нарешті, коли макрос закінчиться, усі вкладення зображень вихідного повідомлення електронної пошти будуть роздруковані на одній сторінці, як на наступному скріншоті:

Справа з пошкодженими файлами Outlook

Зі збільшенням кількості даних, що зберігаються у вашому Outlook, ваш файл Outlook стає вразливим. Він може бути скомпрометований через різні внутрішні та зовнішні фактори. Крім того, важко передбачити корупцію в Outlook. Отже, що ви можете зробити, це забезпечити негайне та ефективне порятунок при зустрічі з корупцією Outlook. Наприклад, ви повинні мати спеціаліста Ремонт PST інструмент, як DataNumen Outlook Repair поблизу. Він буде сканувати та відновлювати пошкоджені файли, як бриз.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі оговтуватися Sql Server та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com