Як швидко знайти абзаци з одним реченням у вашому документі Word

У цій публікації ми хочемо показати вам швидкий спосіб знайти всі абзаци з одним реченням у вашому документі Word за допомогою VBA.

Час від часу деякі документи можуть мати дуже конкретні вимоги до форматування та структури. Наприклад, вам може не дозволити мати абзаци лише з одним реченням. Ці абзаци важко розпізнати, але це вимагає часу, особливо це довгий документ.

Сьогодні ми запропонуємо вам швидкий спосіб вказати всі абзаци з одним реченням у вашому документі.

Знайдіть усі абзаци з одним реченням в одному документі

1. По-перше, Word зараховує крапку як речення. Отже, якщо є такі слова, як "пан" або “пані”, Word розглядає це як речення. Щоб виключити таке відволікання, вам потрібно замінити слово "пан" з “містером”. А коли закінчите знаходити абзац одного речення, ви можете змінити їх назад. Щоб замінити слова, ви можете звернутися за цим посиланням: Як знайти та замінити кілька елементів у вашому документі Word
2. По-друге, натисніть “Alt + F11”, щоб запустити редактор VBA.
3. Потім натисніть «Звичайний» проект.
4. Клацніть на вкладці «Вставка» на рядку меню та виберіть «Модуль» у спадному меню.
5. Далі двічі клацніть на модулі, щоб відкрити його.
6. Вставте наступні коди в модуль:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. І останнє, але не менш важливе, натисніть кнопку «Виконати» або натисніть «F5».

Ви отримаєте таке вікно повідомлення про те, що роботу виконано.

Знайдіть усі абзаци з одним реченням у кількох документах

1. Для початку вам потрібно помістити всі цільові документи в папку.
2. Потім встановіть і запустіть наведений нижче макрос:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. У відкритому вікні “Огляд” виберіть папку, в якій ви зберігаєте документи, і натисніть “OK”.

Потім макрос виділить усі абзаци з одним реченням і залишить документи відкритими. Якщо документ не містить абзацу з одним реченням, його буде закрито. Крім того, є вікно повідомлення, яке вказує кількість абзаців з одним реченням у кожному документі.

Справляйтеся з інцидентом втрати даних

Помилки користувачів та раптове відключення електроенергії можуть призвести до загибелі Word. Хоча згорнуте Word може не лише впливати на щоденну роботу, але і призвести до пошкодження документаЦе аж ніяк не найдратівливіша частина катастрофи з даними. Краще негайно скористатися послугою відновлення, щоб відновити дані.

Вступ автора:

Віра Чень є експертом з відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновити Excel та pdf ремонт програмних продуктів. Для отримання додаткової інформації відвідайте WWW.datanumen.com