Як швидко експортувати загальний час, витрачений на зустрічі Outlook у кожній кольоровій категорії

Якщо ви хочете створити звіт про загальний час, який ви витрачаєте на зустрічі в кожній кольоровій категорії, ви можете скористатися методом, представленим у цій статті. Це може допомогти вам зробити це швидко, без необхідності підраховувати вручну.

Багато користувачів звикли записувати більшість своїх дій у календарі Outlook. Також, щоб легше керувати ними та розрізняти їх, вони призначають кожній із них категорії. У цьому випадку деякі користувачі хочуть створити звіт, що показує загальний час, витрачений на елементи календаря в кожній кольоровій категорії. Безсумнівно, підраховувати та вводити дані вручну складно. Тому тут ми поділимося способом, який може виконати це завдання одним простим клацанням миші.

Експортуйте загальний час, витрачений на зустрічі в кожній кольоровій категорії

1. Перш за все, запустіть програму Outlook.
2. Потім, увійшовши у вікно Outlook, ви можете натиснути кнопки Alt + F11.
3. Згодом ви отримаєте доступ до вікна “Microsoft Visual Basic for Applications”.
4. Далі вам потрібно буде ввімкнути «Бібліотеку об’єктів Microsoft Excel». Ви можете натиснути «Інструменти» > «Довідка», щоб зробити це.
5. Потім вам слід знайти та відкрити модуль, який не використовується.
6. Після цього вам потрібно скопіювати наступний код VBA в цей модуль.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Нарешті, ви можете запустити цей макрос, незалежно від того, що натискаєте піктограму «Виконати» на панелі інструментів або натискаєте кнопку «F5».
8. Потім від вас вимагатимуть вибрати конкретний календар.
9. Після вибору та натискання кнопки «OK» макрос продовжить працювати. Після його завершення з’явиться новий файл Excel, який відображатиметься у фоновому режимі.
10. Ви можете отримати до нього доступ. Це буде виглядати так:

Слідкуйте за потенційними загрозами навколо вашого Outlook

Користувачам Outlook слід звертати увагу на всі потенційні ризики, включаючи невідомі вкладення електронної пошти, вбудовані посилання та людські помилки. В іншому випадку ваш Outlook може бути пошкоджений у будь-який час. Крім того, необхідністю є регулярне резервне копіювання даних Outlook та підтримка спеціалізованого інструменту ремонту. DataNumen Outlook Repair є одним із найбільш рекомендованих інструментів для виправлення. Він може ремонт Outlook проблеми за мить.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com