Як швидко приєднати останній змінений файл у папці Windows до електронної пошти Outlook

Іноді вам може знадобитися швидкий пошук та приєднання останнього зміненого файлу в певній папці Windows до електронної пошти Outlook. У цьому випадку ви можете використовувати метод, представлений у цій статті.

Деякі користувачі хочуть, щоб Outlook швидко знаходив і додавав до електронного листа останній змінений файл у папці Windows, наприклад, нещодавно створений, змінений або збережений файл. Однак Outlook не пропонує такої прямої та вбудованої функції. Тому далі ми розглянемо фрагмент коду VBA, який може легко це реалізувати.

До електронної пошти приєднайте останній змінений файл у папці Windows

1. З самого початку вам слід запустити програму Outlook.
2. Потім, потрапивши в головне вікно Outlook, ви можете натиснути кнопки Alt + F11.
3. Далі ви успішно відкриєте вікно редактора Outlook VBA.
4. Згодом вам слід знайти та відкрити модуль, який не використовується.
5. А потім скопіюйте та вставте наступний код VBA у це вікно модуля.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Після цього ви можете вийти з поточного вікна редактора VBA і додати новий макрос на панель швидкого доступу або стрічку вікна повідомлення.
7. Пізніше вам потрібно змінити рівень захисту макросів Outlook на низький.
8. Зрештою ви можете спробувати.

• По-перше, створіть і складіть нову електронну пошту Outlook, як зазвичай.
• Потім натисніть кнопку макросу на панелі швидкого доступу, як на малюнку нижче:
• Далі вам потрібно буде вибрати вихідну папку Windows і натиснути “OK”.
• Якщо у вибраній папці Windows є такий файл, ви отримаєте підказку, як на наступному знімку екрана:
• Якщо натиснути "Так", цей файл буде вкладено відразу.

Вирішуйте проблеми з Outlook якомога швидше

Кожного разу, коли ви стикаєтесь із будь-якими проблемами Outlook, рекомендується вирішувати їх якомога швидше. У цій ситуації вам краще підготувати надійний Виправлення в Outlook інструмент заздалегідь, наприклад DataNumen Outlook Repair. Він здатний виправити помилки PST та ефективно врятувати ваші дані Outlook.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений mdf та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com