Як автоматично використовувати різні кольори шрифтів для відповіді та пересилання електронних листів за допомогою Outlook VBA

За замовчуванням ви не можете дозволити Outlook автоматично використовувати різні кольори шрифту для відповіді та пересилання електронних листів. Тому, якщо у вас є така вимога, ви можете прочитати це сost навчитися розумному підходу.

Outlook дозволяє лише вказати шрифт, що використовується для відповіді та пересилання електронних листів. Ви можете перейти до «Файл»> «Параметри». Потім у меню «Параметри Outlook» перейдіть на вкладку «Пошта» та натисніть кнопку «Канцтовари та шрифти…». У наступному вікні ви можете побачити кнопку «Шрифт» у розділі «Відповідь або пересилання повідомлень». Клацніть на ньому, і тоді ви зможете встановити певний колір шрифту для відповіді та пересилання електронних листів.

Однак багато користувачів сподіваються використовувати різні кольори шрифту для відповіді або пересилання електронних листів. Хоча Outlook не надає жодних прямих функцій для цього, він все одно може бути реалізований за допомогою коду VBA. Тепер читайте далі, щоб отримати такий фрагмент коду VBA.

Автоматично використовуйте різні кольори шрифтів для відповіді та пересилання електронних листів

1. Для якtart, запустіть програму Outlook.
2. Потім запустіть редактор VBA з посиланням на “Як запустити код VBA у своєму Outlook».
3. Далі, відповідно до “Як додати бібліотеку об’єктаrary Довідка у VBA“, Додайте посилання на„ MS Word Object Librarу ”.
4. Згодом скопіюйте наступний код у проект “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Після цього відпtart Outlook, щоб активувати цей макрос.
6. Нарешті, можна спробувати.

• Виберіть або відкрийте електронний лист.
• Потім натисніть кнопку «Відповісти». Відповідаючи на електронну пошту, ви можете ввести кілька слів у тексті. Колір шрифту повинен бути рожевим.
• Або натисніть кнопку “Відповісти всім”. У новій пошті "відповідь на всі" введіть слова в тілі. Колір шрифту, безумовно, зелений.
• Так само натисніть кнопку «Вперед». У листі, що пересилає, нові слова будуть показані синім кольором.

Зверніться до надійного програмного забезпечення

У разі Корупція в Outlook, Мost користувачі, як правило, вдаються до програм для відновлення Outlook. На ринку існує велика кількість таких програм. А деякі з них навіть безкоштовні. Тим не менше, вам слід остерігатися тих, хто з невідомих джерел, оскільки вони можуть погіршити та погіршити поточний випадок. Вам слід скористатися допомогою надійного та досвідченого інструменту, наприклад DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджений sql та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com