Як автоматично взяти перший рядок тексту як тему перед надсиланням електронної пошти Outlook без теми

Деякі користувачі бажають, щоб Outlook автоматично приймав перший рядок тіла електронної пошти як тему під час надсилання електронного листа без теми. Тепер, у цій статті ми представимо метод реалізації цього за допомогою коду VBA.

Кілька користувачів часто забувають ввести тему під час складання та надсилання електронного листа. Таким чином, зазвичай вони сподіваються, що Outlook може автоматично заповнити тему першим рядком тіла електронної пошти, якщо вихідний електронний лист не має теми. Далі ми поділимося з вами простим та зручним методом.

Автоматично взяти перший рядок основного тексту як тему перед надсиланням електронного листа без теми

1. З самого початку запустіть програму Outlook.
2. Потім, дотримуючись кроків у “Як запустити код VBA у своєму Outlook“, Ви можете потрапити до редактора VBA.
3. Далі, у редакторі VBA, додайте посилання на “MS Word Object Library "відповідно до"Як додати бібліотеку об’єктаrary Довідка у VBA».
4. Пізніше скопіюйте наведений нижче код у проект “ThisOutlookSession”.

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

5. Після цього поставте курсор у “Application_Startup ”і натисніть“ F5 ”.
6. Нарешті, можна спробувати.

• Спочатку створіть і складіть електронний лист із лише порожньою темою.
• Потім натисніть кнопку «Надіслати».
• Пізніше ви отримаєте повідомлення з проханням взяти перший рядок тексту як предмет.
• Поки ви натискаєте кнопку «Так», перший рядок тіла електронної пошти буде витягнуто та використано як тему, а електронне повідомлення буде розіслано.

Бережіть свої дані Outlook у безпеці

Безумовно, у вашому Outlook є кілька важливих електронних листів та інших елементів. Таким чином, ви, мабуть, не бажаєте стикатися з втратою даних Outlook. Потім вам доведеться виконати деякі дії, наприклад, робити регулярні резервні копії даних Outlook, навчитися використовувати вбудований інструмент ремонту для виправити Outlook помилок та підготовка надійної утиліти зовнішнього відновлення. DataNumen Outlook Repair є хорошим вибором завдяки високій швидкості відновлення PST.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновлення SQL та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com