Як пакетно експортувати фотографії та інформацію кількох контактів за допомогою Outlook VBA

Рішення для Outlook Вересень 29, 2025
Поділитися зараз:

Якщо ви хочете вилучити фотографії контактів та їх основну інформацію в папку на локальному диску партіями, вам потрібно використовувати Outlook VBA. Ця стаття навчить вас докладно цього досягти.

Outlook дозволяє експортувати контактну інформацію за допомогою функції «Імпорт та експорт». Ви можете перейти до «Файл»> «Друк»> «Імпорт»> «Експорт у файл».

Експорт у файл

Однак ця функція не дозволяє експортувати фотографії контактів. Таким чином, якщо ви хочете отримати як контактну інформацію, так і фотографії, вам доведеться повернутися до Outlook VBA. Далі наведено коди VBA та кроки, які дозволяють зберегти фотографії контактів у визначеній локальній папці та витягти контактну інформацію у текстовий файл.

Пакетний експорт фотографій та інформації декількох контактів

  1. Перш за все запустіть Outlook і натисніть клавіші “Alt + F11”.
  2. Тоді ви отримаєте доступ до редактора VBA. Тепер вам слід відкрити модуль, який не використовується, або створити новий модуль за допомогою «Вставка»> «Модуль».
  3. Згодом скопіюйте та вставте наступні коди VBA в новий модуль.
Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Коди VBA - пакетний експорт кількох контактних фотографій та інформації

Примітка: Зазначені вище коди експортують фотографії та інформацію контактів у папку контактів за замовчуванням. Ви можете змінити вказані контакти.

  • Якщо ви хочете експортувати фотографії та інформацію контактів у поточно відкриту папку, вам слід замінити “Set objContacts = ... ..” на:
Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items
  • Якщо ви сподіваєтесь лише експортувати фотографії та інформацію вибраних контактів, ви можете використовувати такі рядки:
Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection
  1. Після цього ви можете закрити редактор VBA і продовжити додавати новий проект на панель швидкого доступу, як зазвичай.Додайте новий проект на панель інструментів доступу Qucik
  2. Нарешті, ви можете натиснути кнопку макросу на панелі швидкого доступу. Фотографії та інформація контакту одразу будуть експортовані до вказаної папки на локальному диску.Експортуйте фотографії та інформацію про контакти

Ви можете відкрити один текстовий файл, в якому буде перелічена основна інформація, наприклад, наступний знімок екрана:

Основна контактна інформація у текстовому файлі

Виправити несподівану корупцію в Outlook

Безперечний факт, що Outlook є вразливим. Отже, якщо ви страждаєте від корупції в Outlook, спершу потрібно заспокоїтись. Тоді ви можете продовжувати ремонт пошкоджена електронна пошта PST Outlook. Ви можете скористатися інструментом ремонту вхідних, щоб спробувати. Якщо це не вдається, то вам нічого не залишається, як використовувати набагато потужніший інструмент, такий як DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновлення пошкодженої бази даних та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com

Поділитися зараз:

Коментарі закриті.