Як автоматично встановити різний час нагадування для зустрічей Outlook у різних кольорових категоріях

Якщо ви класифікуєте наради Outlook за кольоровими категоріями і хочете встановити різний час нагадування для нарад у різних кольорових категоріях, ви можете звернутися до цієї статті. Тут ми навчимо вас реалізовувати це за допомогою Outlook VBA.

Наприклад, ви розділяєте зустрічі на дві групи. Одна має колірну категорію «Виїзна», оскільки місце проведення зустрічі знаходиться занадто далеко, а інша – колірну категорію «На місці», оскільки місце проведення знаходиться прямо тут. Тепер ви хочете, щоб Outlook міг автоматично встановлювати час нагадування для «виїзної» зустрічі за 1 годину до початку та для «виїзної» зустрічі за 15 хвилин до початку. Розглядаючи цю вимогу, далі ми поділимося швидким методом.

Автоматично встановлювати різні нагадування для зустрічей у різних кольорових категоріях

1. Для початку запустіть програму Outlook.
2. Потім натисніть клавіші “Alt + F11”, щоб відкрити вікно редактора VBA.
3. Далі, у наступному вікні, скопіюйте та вставте код VBA нижче в проект “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Пізніше вам потрібно клацнути на підпрограмі «Application_Startup» і натиснути клавішу «F5», щоб запустити цей макрос.
5. Відтоді кожен раз, коли до календаря за замовчуванням додається нова зустріч або ви змінюєте існуючу, Outlook автоматично перевіряє категорії зустрічі та автоматично встановлює інший час нагадування.

Усунення помилок Outlook

Час від часу з Outlook можуть виникати різні проблеми. Тому користувачам надзвичайно важливо навчитися вирішувати проблеми з Outlook. Для початку краще регулярно створювати резервні копії даних Outlook. Крім того, якщо це можливо, рекомендується мати надійний накопичувач. Ремонт Outlook інструмент поблизу, наприклад DataNumen Outlook Repair. Він може сканувати ваш файл PST, щоб з’ясувати проблеми Outlook, а потім легко їх вирішити.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновлення SQL та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com