Як автоматично реєструвати загальну кількість вхідних листів щодня у файлі Excel

Ця стаття навчить вас, як дозволити програмі Outlook автоматично підраховувати, скільки електронних листів ви отримували щодня, і записувати номер у файл Excel.

Багато користувачів повинні підрахувати загальну кількість електронних листів, що отримуються щодня. Крім того, для більш зручної перевірки в майбутньому багато хто звик записувати загальний підрахунок у файл Excel. У цьому випадку, звичайно, ви можете обрати підрахунок і запис вручну щодня. Однак це трохи клопітно. І ви можете забути робити це іноді. Тому ви повинні бажати зручного методу, який може змусити Outlook автоматично це робити. У відповідь на цю вимогу ми навчимо вас, як використовувати VBA, щоб реалізувати її в наступному.

Автоматично реєструйте загальну кількість вхідних листів щодня у файлі Excel

1. З самого початку запустіть програму Outlook.
2. Потім натисніть комбінації клавіш “Alt + F11” у головному вікні Outlook.
3. Далі у спливаючому вікні редактора VBA відкрийте проект “ThisOutlookSession”.
4. Згодом скопіюйте та вставте в цей проект наступні коди VBA.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Далі підпишіть цей код і змініть параметри макросів Outlook, щоб дозволити підписані макроси.
6. Після цього потрібно щодня створювати повторювані завдання.

• По-перше, натисніть кнопку «Нове завдання» на панелі завдань.
• У спливаючому вікні «Нове завдання» натисніть кнопку «Повторення».
• Потім у наступному діалоговому вікні виберіть “Щодня”, “Кожні 1 день (дні)” та “Без дати завершення” і, нарешті, натисніть “OK”.
• Пізніше змініть тему завдання та нагадування відповідно до ваших потреб.
• Зрештою натисніть кнопку «Зберегти та закрити».

7. Відтепер щоразу, коли сповіщатиме про нагадування про це завдання, Outlook автоматично підраховуватиме електронні листи, отримані вчора, а потім записуватиме їх у файл Excel, як на наступному скріншоті:

Втеча від постійної втрати даних PST

Ніхто не бажає приймати постійну втрату даних PST. Однак файл PST Outlook схильний до пошкодження. Отже, ви повинні вжити достатніх запобіжних заходів, таких як забезпечення послідовного та сучасного резервного копіювання даних PST та підтримка потужних Відновлення PST інструмент поблизу, як DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі sql ремонт та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com