3 методи імпорту електронних листів із папки Windows у ваш Outlook

Можливо, ви зберегли кілька електронних листів Outlook у папці Windows. Тепер, якщо ви хочете імпортувати їх назад у папку Outlook, як ви можете це зробити? Ця стаття навчить вас 3 способам.

Як ми всі знаємо, Outlook надає вбудовану опцію - «Зберегти як», за допомогою якої ви можете зберігати електронні листи в папці Windows. Однак у вас немає можливості повторно додавати експортовані електронні листи назад до папки Outlook. Отже, якщо ви хочете імпортувати електронні листи Outlook назад до Outlook, як ви можете це реалізувати? Далі ми навчимо вас 3 методам. Ви можете вибрати будь-який відповідно до ваших уподобань.

Спосіб 1: Перетягніть і відпустіть, щоб імпортувати

1. З самого початку вам потрібно отримати доступ до вихідної папки Windows, в якій зберігаються електронні листи Outlook для імпорту в Outlook.
2. Потім запустіть програму Outlook.
3. Далі відкрийте папку Outlook, до якої потрібно імпортувати електронні листи.
4. Згодом вам потрібно звузити як вікно папки Windows, так і вікно Outlook, поки ви не зможете їх переглянути тим часом.
5. Після цього, у папці Windows, ви можете вибрати одну з електронних листів Outlook, а потім натиснути “Ctrl + A”, щоб вибрати їх усі.
6. Пізніше ви зможете перетягнути вибрані електронні листи до видимої папки Outlook, наприклад, наступний знімок екрана:
7. Нарешті, ви побачите, що всі електронні листи Outlook були імпортовані з папки Windows в папку Outlook, як показано нижче:

Спосіб 2: Використовуйте “CreateItemFromTemplate” у VBA

1. Для початку у головному вікні Outlook натисніть клавіші «Alt + F11».
2. Далі ви отримаєте доступ до вікна редактора Outlook VBA.
3. Потім скопіюйте наступний код VBA у порожній модуль.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Далі ви можете натиснути клавішу F5 у поточному вікні модуля, щоб запустити макрос.
5. Після цього вам потрібно перейти до вихідної папки Windows у спливаючому діалоговому вікні.
6. Нарешті, після вибору вихідної папки, всі елементи Outlook у цій папці будуть імпортовані у заздалегідь визначену папку Outlook.
7. Примітка: таким чином, імпортовані електронні листи - це всі нові електронні листи, які ви можете складати за бажанням, як на наступному скріншоті:

Спосіб 3: Використовуйте “OpenSharedItem” у VBA

1. Як і Метод 2, скопіюйте наступні коди VBA в інший модуль.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Потім запустіть цей макрос, натиснувши клавішу “F5”.
3. Далі виберіть вихідну папку.
4. Врешті-решт усі електронні листи будуть імпортовані як зображення нижче:

Порівняння

Засоби для блокування пошкодження даних PST

Як ми всі знаємо, Outlook постачається з попередньо встановленим вбудованим інструментом - scanpstЗдебільшого він здатний вирішити невеликі проблеми. Однак, якщо проблеми серйозні, вбудований інструмент, як правило, дасть збій. Тому краще звернутися до потужнішого інструменту, такого як DataNumen Outlook Repair.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі SQL Server корупція та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com