3 макро - способи швидкого перетворення документів Word у PDF Файли

Поділитися зараз:

У цій статті ми зосередимося на наданні вам 3 макросів, які ви можете використовувати для швидкого перетворення документів Word pdf файли.

У програмі Word 2003 на рядку меню є піктограма. Одним клацанням миші користувачі можуть миттєво запустити вікно «Зберегти як» та зберегти документ у pdf Формат.Зберегти як PDF Іконка

Однак, як ви помічаєте, макет у Word 2010 сильно змінюється. І користувачі повинні натиснути вкладку «Файл», а потім команду «Зберегти як», щоб запустити вікно «Зберегти як». Більше того, вам потрібно вручну вибрати тип збереження, перш ніж натиснути кнопку «Зберегти».Виберіть Зберегти тип

З усіма цими кліками це недостатньо швидко. Тому в цій публікації ми хотіли б показати макрос-спосіб зробити це.

Макрос 1: Швидко запустіть вікно “Зберегти як”

  1. Перш за все, натисніть вкладку «Розробник», а потім виберіть команду «Visual Basic», щоб відкрити редактор VBA. Звичайно, два кліки потрібно зробити, коли вкладка «Розробник» вже відображається. Альтернативний спосіб – натиснути «Alt+ F11».Клацніть «Розробник» -> Клацніть «Visual Basic»
  2. По-друге, натисніть проект «Звичайний».
  3. По-третє, натисніть «Вставити», а потім виберіть «Модуль» у меню списку.
  4. Тепер двічі клацніть на модулі, щоб показати область редагування.Клацніть «Звичайний» -> Клацніть «Вставити» -> Клацніть «Модуль»
  5. Далі вставте такі коди:
Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub
  1. Потім натисніть «Виконати».Вставте макрос TriggerSaveAsWindow-> натисніть "Виконати"

Тепер є вікно «Зберегти як». І тип збереження вже встановлений у форматі pdf. Залишилося лише натиснути кнопку «Зберегти». Цей макрос дозволяє змінити ім'я файлу за потреби.

Макрос 2: Безпосереднє збереження файлів Word у PDF

Якщо деякі люди хочуть зберегти файл безпосередньо в pdf без перегляду імені файлу, ось макрос, який потрібен.

  1. Перш за все, повторіть перші 4 кроки вище.
  2. Далі вставте замість цього такі коди:
'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub
  1. Подібним чином натисніть кнопку «Виконати».

Макрос 3: Пакетне перетворення файлів Word Docx у PDF-файли

  1. Помістіть усі файли docx спочатку в одну папку.
  2. Виконайте наведені вище кроки, щоб відкрити область редагування.
  3. Потім вставте макрос, що лунає:
Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub
  1. Ніколи не забувайте натискати кнопку «Виконати».

Примітка:: У кодах “strFolder = “C: \ Users \ Test \ Desktop \ Test Files \”","“C: \ Users \ Test \ Desktop \ Test Files \” ” - шлях до папки. Не забудьте змінити його відповідно.

Після запуску цього макросу PDF-файли будуть збережені в тій самій папці, де зберігаються документи Word.Ефект

Захистіть файли як можете

Існують профілактичні заходи, а також дії після стихійного лиха для відновлення пошкоджених файлів. Якщо ви регулярно створюєте резервні копії своїх файлів, повернення оригінального файлу буде дуже простим. Правда в тому, що мало хто може дотримуватися свого плану резервного копіювання, що збільшує ризик втрати цінних даних. За таких обставин саме час вдатися до просунутого... Інструмент виправлення корупції в документі Word.

Вступ автора:

Віра Чень є експертом з відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі пошкоджене виправлення та pdf ремонт програмних продуктів. Для отримання додаткової інформації відвідайте WWW.datanumen.com

Поділитися зараз:

Коментарі закриті.