2 способи надрукувати списки завдань Outlook з різними категоріями на різних сторінках

Якщо для завдань Outlook ви призначили різні кольорові категорії і тепер хочете надрукувати списки завдань з різними категоріями на різних сторінках, ви можете звернутися до цієї статті. Тут ми поділимося з вами двома методами, щоб його отримати.

Для того, щоб класифікувати та добре керувати своїми завданнями, можливо, ви застосували кольорові категорії до своїх завдань. Тепер, якщо ви хочете роздрукувати списки своїх завдань з різними категоріями на різних сторінках, будь ласка, читайте далі. Далі ми представимо вам 2 способи отримати його.

Спосіб 1: Друк списків завдань вручну по одному

1. По-перше, в Outlook відкрийте панель «Завдання».
2. Потім відкрийте папку Завдання.
3. Потім натисніть «Ctrl + E», щоб активувати стрічку «Пошук».
4. Після цього на вкладці «Пошук» натисніть кнопку «Категоризувати».
5. Зі спадного списку виберіть кольорову категорію.
6. Тоді у списку залишаться лише завдання з обраною категорією.
7. Тепер перейдіть до «Файл»> «Друк», щоб роздрукувати цей список завдань.
8. Згодом таким же чином роздруковуйте списки завдань з іншими кольоровими категоріями одну за одною вручну.

Спосіб 2: Пакетний друк списків завдань VBA

1. З самого початку запустіть редактор VBA відповідно до “Як запустити код VBA у своєму Outlook».
2. Потім додайте посилання на «Бібліотеку об’єктів MS Excel», як зазначено в «Як додати посилання на бібліотеку об'єктів у VBA».
3. Далі скопіюйте наступний код VBA в модуль.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Потім натисніть кнопку «F5», щоб негайно запустити цей макрос.
5. Коли макрос закінчиться, списки завдань з різними категоріями будуть надруковані на різних сторінках, як показано на наступному скріншоті.

Поверніть цінні дані із компрометованого файлу PST

Якщо ви підпадаєте під недоступний файл PST, ваш наступний крок, безсумнівно, буде Ремонт PST. У цьому випадку спочатку ви можете спробувати інструмент відновлення папки "Вхідні". Якщо це не вдається, ви можете спробувати інший зовнішній інструмент, наприклад DataNumen Outlook Repair. Він може швидко відновити дані PST.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі відновити mdf - - та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com