2 швидкі способи експорту списку всіх позначених електронних листів Outlook до Excel

Якщо ви хочете експортувати список усіх позначених електронних листів із вашої поштової скриньки Outlook до Excel, ви можете скористатися будь-яким із 2 методів, наведених у цій статті.

Наприклад, щоб вчасно обробляти всі позначені електронні листи або ділитися ними з кимось іншим, ви можете сподіватися експортувати їх на аркуш Excel. Тут ми представимо 2 підходи до його реалізації. Перший використовує стандартну функцію "Імпорт та експорт" після пошуку позначених електронних листів. Чесно кажучи, це трохи нудно. Таким чином, в останньому, ми навчимо вас більш зручному способу застосування VBA.

Спосіб 1: Експортувати всі знайдені позначені електронні листи вручну

1. Перш за все, натисніть у вікні пошуку над списком розсилки.
2. Потім клацніть на «Усі поштові відправлення» в групі «Область дії» на вкладці «Пошук».
3. Далі натисніть кнопку “Позначений” у групі “Визначити”.
4. Після всіх позначених електронних листів, показаних у списку, виберіть одну пошту та натисніть “Ctrl + A”, щоб вибрати всі.
5. Потім натисніть комбінації клавіш “Ctrl + Shift + V”.
6. У новому діалоговому вікні створіть нову папку під файлом Outlook.
7. Пізніше виберіть нову створену папку та натисніть “OK”, яка перемістить усі знайдені позначені електронні листи до нової папки.
8. Потім натисніть «Файл»> «Відкрити»> «Імпорт»,
9. У спливаючому діалоговому вікні виберіть «Експорт у файл»> «Далі»> «Microsoft Excel 97-2003»> «Далі».
10. На новому екрані виберіть правильну папку та натисніть «Далі».
11. Згодом дотримуйтесь майстрів, щоб завершити “Експорт”.
12. Ви отримаєте новий файл Excel, показаний на наступному знімку екрана.

Спосіб 2: Експортуйте список усіх позначених електронних листів через VBA

1. У програмі Outlook натисніть “Alt + F11”, щоб запустити редактор VBA.
2. Потім увімкніть “Об’єкт MS Excel” відповідно до “Як додати посилання на бібліотеку об'єктів у VBA».
3. Далі скопіюйте код VBA нижче в модуль.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Нарешті, поставте курсор у підпрограму «ExportAllFlaggedEmailsToExcel» і натисніть кнопку «F5».
5. Потім виберіть файл Outlook у новому діалоговому вікні.
6. Коли ви отримаєте запит "Завершено", ви також отримаєте новий файл Excel, як зображення нижче.

Захистіть свій Outlook від корупції

Outlook схильний до помилок та пошкоджень, тому захист наших даних Outlook є дуже складним завданням для нас. Безсумнівно, найефективнішим та найпрактичнішим способом є регулярне резервне копіювання даних Outlook. Крім того, нам також необхідно мати потужний та надійний інструмент для виправлення помилок Outlook, такий як DataNumen Outlook Repair. Це стане в нагоді, якщо інструмент для ремонту вхідних - не робить ефекту.

Вступ автора:

Ширлі Чжан - експерт із відновлення даних у DataNumen, Inc., яка є світовим лідером у галузі технологій відновлення даних, в тому числі фіксувати SQL Server та перспективні програмні продукти для ремонту. Для отримання додаткової інформації відвідайте WWW.datanumen.com