Yinelenen Alıcıları VBA ile Outlook E-postanızdan Hızlı Bir Şekilde Kaldırma

Geçerli e-postanın "Kime" alanına kişi grupları eklerseniz, aralarında yinelenenler olabilir. Bu makale, yinelenen alıcıları hızlı bir şekilde kaldırmak için VBA'yı nasıl kullanacağınızı öğretecektir.

Bir e-posta oluştururken, yalnızca kişileri değil, aynı zamanda kişi gruplarını da alıcı olarak eklerseniz, kişi grupları varsayılan olarak daraltıldığı için bazen yinelenen alıcılar olabilir. Bu durumda, yinelenenleri bulmak istiyorsanız, önce iletişim gruplarını genişletmeniz ve ardından alıcıları manuel olarak karşılaştırmanız gerekir ki bu, bir önceki makalemde ayrıntılı olarak tanıtıldı- “Yinelenen Alıcıları Outlook E-postalarınızdan Kaldırma”. Hiç şüphe yok ki, çok sıkıcı. Bu nedenle, birçok kullanıcı yinelenen alıcıları kaldırmanın hızlı bir yolunu özlüyor. Aşağıda, size Outlook VBA ile almayı öğreteceğiz.

Outlook E-postanızdaki Yinelenen Alıcıları Hızla Kaldırın

1. İlk etapta, Outlook uygulamanızı başlatın.
2. Ardından “Geliştirici” sekmesine geçin ve “Visual Basic” butonuna tıklayın veya “Alt + F11” tuşlarına basın.
3. Sonraki "Microsoft Visual Basic for Applications" penceresinde boş bir modül açabilirsiniz.
4. Ardından, aşağıdaki VBA kodlarını kopyalayıp bu modüle yapıştırın.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Bundan sonra, yeni VBA projesini mesaj penceresinin Hızlı Erişim Araç Çubuğuna ekleyebilirsiniz.
6. Daha sonra Outlook makro güvenlik düzeyinizi düşük olarak ayarlamanız gerekir.
7. Sonunda bir deneyebilirsin.

• İlk olarak, her zamanki gibi bir e-posta oluşturun.
• Ardından, "Kime" alanına kişi grupları ve kişileri ekleyin.
• Ardından, Hızlı Erişim Araç Çubuğundaki yeni makro düğmesine tıklayabilirsiniz.
• Outlook hemen kişi gruplarını otomatik olarak genişletecek ve ardından yinelenen alıcıları kaldıracaktır.

Değerli Outlook Verilerinizi Koruyun

Outlook çökmeye eğilimli olduğundan, Outlook verileriniz bozulmaya karşı hassastır. Bu nedenle, Outlook dosyanızı korumak için çok çaba sarf etmeniz gerekiyor. Her şeyden önce, PST dosyanızı düzenli olarak yedeklemeniz gerekir. kolaylaştıracak bozuk PST tamirat. Buna ek olarak, kullanışlı bir güçlü düzeltme aracı hazırlamanız daha iyi olur, örneğin DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. mdf düzeltme ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com