Tüm Alt Klasörleri ve Öğeleri Olan Bir Outlook Klasörünü Bir Windows Klasörüne Hızlı Bir Şekilde Dışa Aktarma

Bazen, tüm alt klasörleri ve öğeleri içeren bir Outlook klasörünü bir Windows klasörüne toplu olarak dışa aktarmak isteyebilirsiniz. Bu makale size Outlook VBA'yı uygulayan böyle bir yöntemi öğretecektir.

Aynı klasör yapısındaki tüm öğelerle bir Outlook klasörünü yerel sürücüye vermek istediğinizde, kaydetmeyi ve manuel olarak dışa aktarmayı seçerseniz, bu çok zaman alacaktır. Bu nedenle, neden herhangi bir dışa aktarma aracı veya VBA kodu gibi başka yollara başvurmuyorsunuz? Burada size böyle bir VBA kodunu açıklayacağız. Bir esinti gibi başarmanıza izin verecektir.

Outlook Klasöründeki Tüm Alt Klasörleri ve Öğeleri Windows Klasörüne Aktarın

1. Öncelikle Outlook programınızı başlatın.
2. Ardından ana Outlook penceresinde, “Alt + F11” tuş kısayollarına basın.
3. Daha sonra “Microsoft Visual Basic for Applications” penceresi açılacaktır.
4. Daha sonra boş bir modül açmanız ve aşağıdaki VBA kodlarını içine kopyalamanız gerekir.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Bundan sonra, Outlook'unuzun makro ayarlarında makrolara izin verdiğinden emin olmanız gerekir.
6. Sonunda, bir deneyebilirsin.

• İlk olarak, yeni makro penceresine geri dönün.
• Ardından “ExportFolderWithAllItems” alt programına tıklayın.
• Daha sonra bu makroyu çalıştırmak için F5 tuşuna basın.
• Bundan sonra, belirli bir klasör seçmeniz gerekir.
• Son olarak “Complete” (Tamamlandı) mesajı geldiğinde önceden tanımlı yerel klasöre erişebilirsiniz. Tüm öğelerin aynı klasör yapısına kaydedildiğini göreceksiniz.

Outlook Çökmelerinden Kaynaklanan Veri Kaybını Önleyin

Belki de daha önce birçok Outlook çökmesiyle karşılaşmışsınızdır. Çoğu zaman, yeniden başlatmanın ardından Outlook normal şekilde çalışmaya devam eder. Ancak, PST dosyamızın bozulduğu durumlar da olabilir. Bu durumda, PST verilerinizi kurtarmak için deneyimli bir araç kullanmak gibi en iyi yöntemleri deneyebilirsiniz. DataNumen Outlook Repair. Yapabiliyor Outlook'u düzelt hataları düzeltin ve güvenliği ihlal edilmiş PST dosyasından hiç ter dökmeden verileri ayıklayın.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server onarım ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com