Outlook'ta "Tümünü Yanıtla" Kullanılırken Orijinal "CC" Alıcılarını Hızlı Bir Şekilde Dışlama

"Tümünü Yanıtla" kullanılırken, yanıt veren e-posta, orijinal e-postanın "CC" alıcılarını "CC" alanına da dahil edecektir. Ancak, bu tür bir alıcıyı hariç tutmak istiyorsanız, bu makalede açıklanan yöntemi kullanabilirsiniz.

Bazen, bir e-postayı orijinal gönderene ve "Kime" alıcılarına yanıtlamak istersiniz. Bu senaryoda, kesinlikle "Tümünü Yanıtla" seçeneğini kullanmayı düşüneceksiniz. Ancak bu sayede orijinal mailin de “CC” alıcıları varsa, “Reply All” e-postası otomatik olarak “CC” alıcılarını “CC” alanına kopyalayacaktır. Onlara cevap vermek istemiyorsanız, onları manuel olarak kaldırmanız gerekir ki bu biraz zahmetlidir. Şimdi, aşağıda, Outlook'un ihtiyaçlarınıza göre bunu otomatik olarak gerçekleştirmesine nasıl izin vereceğinizi öğreteceğiz.

"Tümünü Yanıtla"yı Kullanırken Orijinal "Bilgi" Alıcılarını Hızlı Bir Şekilde Hariç Tutun

1. Öncelikle Outlook'u başlatın.
2. Ardından, önceki makaleyi okuyarak VBA düzenleyicisine erişin – “Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?".
3. Ardından, aşağıdaki VBA kodunu “ThisOutlookSession” projesine kopyalayın.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Ardından, bu yeni projeyi etkinleştirmek için Outlook'unuzu yeniden başlatın.
5. O zamandan beri, “Tümünü Yanıtla” düğmesine her bastığınızda, aşağıdaki resimde gösterildiği gibi, orijinal CC alıcılarını hariç tutmak isteyip istemediğinizi soran bir istem alacaksınız.
6. “Evet”i seçerseniz, Outlook otomatik olarak “CC” alanındaki alıcıları kaldıracaktır.

Outlook Hasarına Karşı Hazırlıklı Olun

Hepimizin bildiği gibi, hiç kimse Outlook hasarından %100 korunabileceğini garanti edemez. Bu nedenle, tüm Outlook kullanıcılarının birçok önlem alması şarttır. Her şeyden önce, en önemlilerinden biri, tutarlı ve güncel bir Outlook veri yedeklemesi tutmaktır. Ardından, gelen kutusu onarım aracını nasıl kullanacağınızı öğrenmek gerekir. Son olarak, deneyimli bir uzmandan yardım almak akıllıca ve tavsiye edilen bir davranıştır. Outlook düzeltmesi yakınlardaki alet, örneğin DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. mdf'yi kurtar ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com