Klasör Yapısını VBA Yoluyla Bir Outlook PST Dosyasından Diğerine Hızla Kopyalama

Klasör yapısını bir Outlook PST dosyasından diğerine kopyalamak istiyorsanız, bu makalede tanıtılan ve tek seferde almak için VBA'yı nasıl kullanacağınızı öğretecek olan yöntemi kullanabilirsiniz.

Belki de e-postalarınızı daha iyi yönetmek için ana Outlook dosyanızda birkaç özel klasör oluşturmuşsunuzdur. Bu nedenle, yeni bir Outlook PST dosyası oluştururken aynı klasör yapısını uygulamak isteyebilirsiniz. Aslında bir önceki yazımda – “Yeni bir Outlook dosyasında mevcut klasör hiyerarşisini korumak için 2 adım”, bunu başarmak için “Arşiv” özelliğini kullanan geleneksel bir yöntem öğrenebilirsiniz. Yine de, aslında, hala biraz sıkıcı. Bununla karşılaştırıldığında, onu elde etmek için VBA kodlarını kullanmak çok daha hızlı olacaktır. Bu nedenle, aşağıda size ayrıntılı adımları ve kodları anlatacağız.

Klasör Yapısını Bir Outlook PST Dosyasından Diğerine Kopyalayın

1. Öncelikle Outlook programınızı başlatın.
2. Ardından Outlook penceresinde “Alt + F11” tuşlarına basın.
3. Ardından, Outlook VBA düzenleyici penceresine gireceksiniz.
4. Ardından, aşağıdaki VBA kodlarını kopyalayıp yeni bir modüle yapıştırın.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Bundan sonra, makro güvenlik düzeyinizi düşük olarak değiştirin.
6. Daha sonra VBA editör penceresine dönerek makroyu çalıştırmak için “F5” tuşuna basın.
7. Son olarak, makro çalışmayı bitirdikten sonra, “Tamamlandı!” diye soran bir mesaj alacaksınız.
8. Bu noktada, posta gezinme bölmesine gidebilirsiniz. Aşağıdaki görüntü gibi, kaynak PST dosyasıyla aynı klasör yapısında olan yeni bir Outlook Veri Dosyası göreceksiniz:

Moral Bozan PST Sorunlarıyla Başa Çıkın

Outlook PST hataya açık olduğundan, çoğunuz Outlook'ta çeşitli sorunlarla karşılaşmış olmalısınız. Onlarla karşı karşıya kaldığınızda, denemek için öncelikle Outlook gelen kutusu onarım aracını kullanabilirsiniz. Başarısız olursa, daha güçlü bir üçüncü taraf aracı uygulayabilirsiniz, örneğin DataNumen Outlook Repairolabilir Outlook'u düzelt Bir esinti gibi PST hataları.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server düzeltmek ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com