Outlook E-postanızdaki Tüm Katıştırılmış Görüntüleri Hızlı Bir Şekilde Eklere Dönüştürme

İleti gövdesine katıştırılmış tüm resimleri e-posta eklerine hızlı bir şekilde değiştirmek isterseniz, el ile kaldırıp yeniden eklemeniz gerekmez. Bu makalede açıklanan VBA kodunu kullanabilirsiniz.

Bazen, tüm gömülü görüntüleri toplu olarak eklere dönüştürmek isteyebilirsiniz. Örneğin, mesaj gövdesinde çok fazla resim olması, gövdedeki metinleri okumanızı kesintiye uğratır. Bu nedenle, bunları e-posta gövdesinden kaldırmak ve bunun yerine ek olarak eklemek istiyorsunuz. Tabii ki, bunu manuel olarak yapabilirsiniz. Ancak, herhangi bir araç veya VBA kodunun bunu tek seferde alabilmesi daha kolay olmalıdır. Burada size böyle bir VBA kodunu açıklayacağız.

Gömülü Tüm Görüntüleri Hızla Eklere Dönüştürün

1. Öncelikle Outlook programınızı başlatın.
2. Ardından “Geliştirici” sekmesine geçebilir ve “Visual Basic” düğmesine basabilirsiniz.
3. Sonra Outlook VBA editör penceresine gireceksiniz.
4. Ardından, aşağıdaki VBA kodunu boş bir modüle kopyalamanız gerekir.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Bundan sonra, Outlook'unuzun makrolara izin verecek şekilde ayarlandığını onaylamanız gerekir.
6. İsteğe bağlı olarak, buna sık sık ihtiyaç duyuyorsanız, yeni makroyu gelecekte uygun kontrol için Hızlı Erişim Araç Çubuğuna ekleseniz iyi olur.
7. Sonunda bir deneyebilirsin. Bir e-posta seçin veya açın ve ardından Hızlı Erişim Araç Çubuğundaki yeni makro düğmesine tıklayarak makroyu çalıştırın.
8. Hemen, tüm gömülü resimler aşağıdaki ekran görüntüsü gibi eklere dönüştürülecektir:

Değerli Outlook Verilerinizi Korumanın Püf Noktaları

Hepimizin bildiği gibi, Outlook PST dosyası, Word belgeleri veya Excel elektronik tabloları gibi yaygın dosyalarla aynı güvenlik açığına sahiptir. Bu nedenle, virüsler veya yanlış işlemler gibi PST dosyanızdaki tüm risklere dikkat etmelisiniz. Bu nedenle, PST dosyanız için düzenli veri yedeklemeleri yapmanız gerekir. Ayrıca, karşılayabiliyorsanız, sağlam tutmak akıllıca olacaktır. Outlook onarımı araç kullanışlı, gibi DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. mdf'yi kurtar ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com