Bir Windows Klasöründeki Son Değiştirilen Dosyayı Hızlı Bir Şekilde Outlook E-postanıza Ekleme

Bazen, belirli bir Windows klasöründeki son değiştirilen dosyayı hızlı bir şekilde bulup bir Outlook e-postasına eklemek isteyebilirsiniz. Bu durumda, bu makalede açıklanan yöntemi kullanabilirsiniz.

Bazı kullanıcılar, Outlook'un bir Windows klasöründeki en son değiştirilen dosyayı (örneğin en son oluşturulan, değiştirilen veya kaydedilen dosyayı) hızlı bir şekilde bulup e-postaya eklemesini ister. Ancak Outlook, bu tür doğrudan ve yerleşik bir özellik sunmamaktadır. Bu nedenle, aşağıda bunu kolaylıkla gerçekleştirebilecek bir VBA kodu örneği sunacağız.

Bir Windows Klasöründeki Son Değiştirilen Dosyayı E-postaya Ekleyin

1. En başta, Outlook uygulamanızı başlatmalısınız.
2. Ardından, ana Outlook penceresine girdikten sonra “Alt + F11” tuş düğmelerine basabilirsiniz.
3. Ardından, başarılı bir şekilde Outlook VBA düzenleyici penceresine erişeceksiniz.
4. Ardından, kullanılmayan bir modülü bulup açmalısınız.
5. Ardından aşağıdaki VBA kodunu kopyalayıp bu modül penceresine yapıştırın.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Bundan sonra, mevcut VBA düzenleyici penceresinden çıkıp yeni makroyu Hızlı Erişim Araç Çubuğuna veya Mesaj penceresi şeridine eklemeye devam edebilirsiniz.
7. Daha sonra Outlook makro güvenlik düzeyinizi düşük olarak değiştirmeniz gerekir.
8. Sonunda bir deneyebilirsin.

• İlk olarak, her zamanki gibi yeni bir Outlook e-postası oluşturun ve oluşturun.
• Ardından, aşağıdaki görüntüdeki gibi Hızlı Erişim Araç Çubuğundaki makro düğmesine basın:
• Ardından, bir kaynak Windows klasörü seçmeniz ve “Tamam” düğmesine basmanız istenecektir.
• Seçilen Windows klasöründe böyle bir dosya varsa, aşağıdaki ekran görüntüsüne benzer bir bilgi istemi alırsınız:
• “Evet”e bastığınızda, bu dosya hemen eklenecektir.

Outlook Sorunlarını En Kısa Sürede Çözün

Herhangi bir Outlook sorunuyla karşılaştığınızda, bunları mümkün olan en kısa sürede çözmeniz önerilir. Bu durumda, sağlam bir hazırlık yapsanız iyi olur. Outlook düzeltmesi araç gibi önceden DataNumen Outlook Repair. PST hatalarını düzeltme ve Outlook verilerinizi etkili bir şekilde kurtarma yeteneğine sahiptir.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. bozuk mdf ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com