Outlook'unuzdaki Farklı Bayraklı Öğe Türleri için Farklı Varsayılan Hatırlatma Süresini Ayarlama

Varsayılan olarak Outlook, her tür işaretli öğe için varsayılan görev hatırlatma zamanını otomatik olarak kullanır. Yine de, işaretlenen öğeler için öğe türüne göre farklı hatırlatma süresi kullanmak istiyorsanız, bu makaledeki yönteme başvurabilirsiniz.

Outlook, öğe türünden bağımsız olarak tüm işaretli öğeler için varsayılan anımsatıcı zamanı ayarlamanıza olanak tanır. “Dosya” menüsüne gidip “Seçenekler”e tıklayabilirsiniz. Ardından, “Outlook Seçenekleri” penceresinde, aşağıdaki ekran görüntüsünde gösterildiği gibi “Görevler” sekmesinde “Varsayılan hatırlatma zamanı” seçeneğini görebilirsiniz.

Bununla birlikte, çoğu kullanıcı, işaretlenmiş öğeler için farklı hatırlatma saatleri kullanmayı umuyor; örneğin, işaretlenmiş e-postalar için "9:00" ve işaretlenmiş kişiler için "17:30". Şimdi, aşağıda bu örneğe odaklanarak bir yöntem tanıtacağız.

Farklı Bayraklı Öğe Türleri için Farklı Varsayılan Hatırlatma Süresi Ayarlayın

1. Öncelikle Outlook uygulamasını başlatın.
2. Ardından, “ referansıyla Outlook VBA düzenleyicisine erişin.Outlook'unuzda VBA Kodunu Nasıl Çalıştırırsınız?".
3. Sonraki “Microsoft Visual Basic for Applications” penceresinde, aşağıdaki kodu “ThisOutlookSession” projesine kopyalayın.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Ardından, bu makroyu etkinleştirmek için Outlook'u yeniden başlatın.
5. Bundan sonra, bir e-postayı her işaretlediğinizde, hatırlatma zamanı, işaretleme son tarihinde “10:00” olarak ayarlanacaktır.
6. Ve bir kişiyi işaretlediğinizde, hatırlatma zamanı, işaretleme son tarihinde “17:30” olarak ayarlanacaktır.

Outlook Sorunlarını Esnek Bir Şekilde Aşın

Outlook'unuzda her türlü sorunla karşılaşabilirsiniz. Bu nedenle, bunlarla önceden başa çıkmak için bazı önlemleri öğrenmeniz gerekir. Örneğin, Outlook'unuz sık sık yeniden başlatılıyorsa, Office'i onarmanız veya üçüncü taraf eklentilerini devre dışı bırakmanız gerekir, vb. Veya Outlook PST dosyanız tehlikeye girerse, önce şunları deneyebilirsiniz: gelen kutusu onarım aracı. Başarısız olduğunda, güçlü bir harici araca başvurmaya devam edebilirsiniz. DataNumen Outlook Repair.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. mdf kurtarma ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com