Word Belgenizdeki Tüm Köprüleri VBA Aracılığıyla Toplu Olarak Doğrulama

Bu makalede, Word belgenizdeki tüm köprüleri VBA aracılığıyla hızlı bir şekilde toplu olarak doğrulamanın otomatik bir yolunu göstereceğiz.

Bir Word belgesi birçok, hatta yüzlerce köprü içerebilir. Bunların arasında, bazıları sizi doğru bir web sayfasına yönlendirmeyen geçersiz bağlantılardır. Bu nedenle, size bir belgedeki tüm bağlantıları VBA aracılığıyla hızlı bir şekilde kontrol etmenin yolunu sunmak istiyoruz.

Bir Word Makrosu Kurun ve Kaydedin

1. Öncelikle “Alt+F11” ile VBA editörünü açın.
2. Ardından “Normal” projesine tıklayın.
3. Daha sonra araç çubuğu menüsündeki “Ekle” sekmesine tıklayın.
4. Ve menüden “Modül”ü seçin.
5. Düzenleme alanını açmak için modüle çift tıklayın ve aşağıdaki kodları buraya yapıştırın:

Function CheckURL(strURL As String) As Boolean
  Dim objDemand As Object
  Dim varResult As Variant
 
  On Error GoTo ErrorHandler
  Set objDemand = CreateObject("WinHttp.WinHttpRequest.5.1")
 
  With objDemand
    .Open "GET", strURL, False
    .Send
    varResult = .StatusText
  End With
 
  Set objDemand = Nothing
 
  If varResult = "OK" Then
    CheckURL = True
  Else
    CheckURL = False
  End If
 
ErrorHandler:
End Function

Sub ReturnURLCheck()
  Dim objLink As Hyperlink
  Dim strLinkText As String
  Dim strLinkAddress As String
  Dim strResult As String
  Dim nInvalidLink As Integer, nTotalLinks As Integer
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
 
  Set objDoc = ActiveDocument
  nTotalLinks = objDoc.Hyperlinks.Count
  nInvalidLink = 0
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkText = objLink.Range.Text
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        nInvalidLink = nInvalidLink + 1
        strResult = frmCheckURLs.txtShowResult.Text
        frmCheckURLs.txtShowResult.Text = strResult & nInvalidLink & ". Invalid Link Information:" & vbNewLine & _
                                          "Displayed Text: " & strLinkText & vbNewLine & _
                                           "Address: " & strLinkAddress & vbNewLine & vbNewLine
      End If
    Next objLink
 
    frmCheckURLs.txtTotalLinks.Text = nTotalLinks 
    frmCheckURLs.txtNumberOfInvalidLinks.Text = nInvalidLink
    frmCheckURLs.Show Modal
 
  End With
  Application.ScreenUpdating = True
End Sub

Sub HighlightInvalidLinks()
  Dim objLink As Hyperlink
  Dim strLinkAddress As String
  Dim strResult As String
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        objLink.Range.HighlightColorIndex = wdYellow
      End If
    Next objLink
  End With
End Sub

6. Sonra "Kaydet"i tıklayın.
7. Ardından makro için bir düğme atayın. Ayrıntılı bilgi için aşağıdaki makaleye başvurabilirsiniz:

Word'ünüzdeki Makro ve VBA ile Yapıştırılan Metinlerin Biçimlendirmesini Kaldırma

Bir Kullanıcı Formu Oluşturun

Bir kullanıcı formu ile mevcut belgedeki toplam bağlantı sayısını, geçersiz bağlantı sayısını ve daha fazla ayrıntıyı net bir şekilde görebilirsiniz.

1. İlk olarak, araç çubuğundaki “Ekle” ye tekrar tıklayın. Ancak bu sefer “UserForm”u seçin.
2. Daha sonra sol alt köşedeki “Özellikler Penceresini” açmak için “F4”e basın. Pencere boyutu ayarlanabilir.
3. Şimdi kullanıcı formunu “frmCheckURLs” olarak adlandırın.
4. Altyazıyı "URL'leri Kontrol Et" olarak ayarlayın.
5. Ardından yazı tipini uygun şekilde ayarlayın.
6. Daha sonra araç çubuğundaki “Araç Kutusu” düğmesine tıklayın.
7. Şimdi araç kutusundaki “Etiket” e tıklayın. Kullanıcı formunda bir dikdörtgen etiketi sürüklemek için fareyi kullanın.
8. Özellik penceresini etkinleştirmek için etikete tıklayın. Etiket adını "lblInvalidURLs" ve etiket başlığını "Geçersiz URL'ler:" olarak ayarlayın.
9. Ardından, etiket başlığı metni için uygun yazı tipini ve ön rengi seçin.
10. Araç kutusundan “Metin Kutusu”nu seçin ve kullanıcı formuna bir metin kutusu ekleyin. Boyutunu ayarlayın.
11. Ardından metin kutusu adını “txtShowResult” olarak ayarlayın.
12. Yazı tipini ve ön rengi istediğiniz gibi ayarlayın.
13. “MultiLine” öğesini bulun ve “True” olarak ayarlayın.
14. "Kaydırma Çubukları"nı bulun ve dikey bir çubuk seçin.
15. Sonra iki tane daha etiket ve metin kutusu oluşturun.
16. Ardından, ilk etiketi "lblTotalLinks" olarak adlandırın ve başlığı "Bu belgedeki toplam bağlantılar" olarak ayarlayın.
17. Ve ikinci etiketi "lblNumberOfInvalidLinks" olarak adlandırın ve başlığı "Geçersiz bağlantı sayısı" olarak ayarlayın.
18. İlk metin kutusunu "txtTotalLinks" ve ikincisini "txtNumberOfInvalidLinks" olarak adlandırın.
19. Ardından, araç kutusundaki komut düğmesi kontrolünü bulun. Aşağıdaki gibi iki komut düğmesi oluşturun:
20. İlk düğmeyi "cmdbtnClose" ve başlık metnini "Kapat" olarak adlandırın.
21. İkinci düğmeyi "btnCloseAndHighlightInvalidURLs" ve altyazı metnini "Geçersiz URL'leri Kapat ve Vurgula" olarak adlandırın.
22. Daha sonra sırasıyla "Kapat" düğmesine ve "Geçersiz URL'leri Kapat ve Vurgula" düğmesine çift tıklayın. Kodları aşağıdaki gibi girin:

Makroyu Çalıştır

Makroya atadığınız düğmeyi tıklayın. İşte son etki:

Soldaki büyük metin kutusunda başarısız olan her bağlantı hakkında ayrıntılı bilgi görebilirsiniz. Ayrıca, kullanıcı formunu doğrudan kapatmayı veya belgedeki tüm kopuk bağlantıları vurgulayarak kapatmayı seçebilirsiniz.

Word Sorunlarını Dikkatle Ele Alın

Word kolayca hatalara eğilimlidir. Böylece son derece önemli hale gelir Word'ü düzelt Doğru şekilde. Çoğu zaman, yerleşik araç size pek yardımcı olamaz. Bu nedenle, en iyi seçeneğiniz üçüncü taraf bir onarım aracı edinmektir.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. onarım xlsx hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com