Bir E-postanın Kategorilerini Outlook'ta Tüm Yanıtlarına ve Yönlendirmelerine Otomatik Olarak Uygulama

Bir e-postayı yanıtlarken veya iletirken aynı kategorileri uygulamak isteyebilirsiniz. Bu yazımızda size bunu VBA kodu ile gerçekleştirmeyi öğreteceğiz.

Orijinal e-postanın tüm yanıtlarına ve yönlendirmelerine aynı renk kategorilerini atamaya alışkınsanız, neden Outlook'un bunu otomatik olarak yapmasına izin vermiyorsunuz? Outlook böyle bir doğrudan özellik sağlamasa da, yine de VBA kodu yardımıyla elde edebilirsiniz. Aşağıda, ayrıntılı adımları ve kodu size göstereceğiz.

Bir E-postanın Kategorilerini Tüm Yanıtlarına ve Yönlendirmelerine Otomatik Uygula

1. En başta, Outlook uygulamasını başlatın.
2. Ardından, Outlook VBA düzenleyicisini çalıştırmak için “Alt + F11” tuşlarına basın.
3. Ardından, aşağıdaki VBA kodunu “ThisOutlookSession” projesine kopyalayın.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Ardından, bu projeyi etkinleştirmek için Outlook'unuzu yeniden başlatın.
5. O zamandan beri, aşağıdaki adımları izleyerek deneyebilirsiniz.

• Öncelikle, bir e-posta seçin ve “İlet” düğmesine basın.
• Ardından, "Seçenekler" sekmesine geçip "Diğer Seçenekler" grubunun sağ alt köşesindeki uzantı simgesine basabileceğiniz bir yönlendirme e-postası görüntülenecektir.
• Ardından, açılır "Özellikler" iletişim kutusunda, bu e-postanın orijinal e-posta ile aynı renk kategorilerine atandığını görebilirsiniz.

Hasarlı Outlook Dosyasını Düzeltin

Outlook'un güvenlik açığı olduğu göz önüne alındığında, Outlook veri kaybını önlemek için pek çok önlem almanız gerekir. Örneğin, periyodik olarak veri yedeklemeleri yapmanız gerekiyor. Ayrıca, katıştırılmış bağlantılar veya ekler de dahil olmak üzere bilinmeyen e-postalara karşı dikkatli olmanız gerekir. Son olarak, en iyi harici düzeltme aracına sahip olmalısınız, örneğin DataNumen Outlook Repair. Maksimum veri almanıza yardımcı olabilir bozuk Outlook dosyası.

Yazar Tanıtımı:

Shirley Zhang, bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. SQL Server düzeltmek ve görünüm onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com