Word Tablonuzdaki Boş Satırları ve Sütunları Silmenin 3 Hızlı Yolu

Bu yazımızda, Word tablonuzdaki boş satır ve sütunları silmenin 3 hızlı yolunu açıklayacağız.

Tablolar, özellikle çeşitli veri türlerini tutarken bir belge için çok önemlidir. Bazen uzun bir tablo bir sayfayı aşabilir ve birkaç sayfaya yayılabilir. Dolayısıyla, bir tablo uzun ve karmaşık hale geldiğinde, onu basitleştirmek için yapabileceğiniz önlemler vardır. Örneğin, gereksiz boş satırları ve sütunları silebilirsiniz.

Aşağıda kullanabileceğiniz 3 yöntem bulunmaktadır.

Yöntem 1: Boş Satırları ve Sütunları Manuel Olarak Silin

1. İlk olarak, boş bir satır veya sütun seçin.
2. Ardından bağlamsal menüyü almak için sağ tıklayın. Menüde, buna göre “Satırları Sil” veya “Sütunları Sil” seçeneğini seçin.

Ne yazık ki, birbirini takip etmeyen birden fazla satır veya sütunu bu şekilde seçip birlikte silemezsiniz. Bu talebiniz için bir önceki yazımıza başvurabilirsiniz: Word Tablonuzdaki Birden Çok Satırı veya Sütunu Toplu Silme İçin 5 Hızlı Yöntem

Yöntem 2: Bir Tablodaki Tüm Boş Satırları ve Sütunları Toplu Silme

Yöntem 1'in sınırlaması vardır. Bu yüzden size bir tablodaki satırları ve sütunları VBA kodları aracılığıyla toplu olarak kaldırmanın yolunu sunacağız.

1. Öncelikle, imleci hedef tablonun içine yerleştirin.
2. İkinci olarak, “Alt+F11” tuşlarına basarak VBA editörünü tetikleyin.
3. Düzenleyicide, önce "Normal" projeye tıklayın.
4. Ardından menü çubuğundaki “Ekle” sekmesine tıklayın.
5. Açılır menüden "Modül"ü seçin.
6. Açmak için modüle çift tıklayın ve aşağıdaki kodları oraya yapıştırın:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Son olarak, menü çubuğundaki "Çalıştır" düğmesine tıklayın veya "F5" tuşuna basın.

Saniyeler içinde, o tablodaki tüm boş satırları ve sütunları kaldıracaksınız.

Yöntem 3: Belgedeki Tüm Tablolardaki Tüm Boş Satırları ve Sütunları Toplu Silme

1. Öncelikle, bir makro yüklemek ve çalıştırmak için yöntem 2'deki adımları tekrarlayın.
2. Ancak bu sefer, o makroyu aşağıdakiyle değiştirin:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Bozuk Belgeyi Kurtar

Günümüzde kayıp verileri geri almanın birden fazla yolu var. Örneğin, yedeklemeler her zaman en öncelikli işlem olmalıdır. Eğer bu, en güncel bilgilere ulaşma ihtiyacınızı karşılamazsa, o zaman başka bir yöntemi deneyebilirsiniz. doktor onarımı aracı.

Yazar Tanıtımı:

Vera Chen bir veri kurtarma uzmanıdır. DataNumendahil olmak üzere veri kurtarma teknolojilerinde dünya lideri olan , Inc. xlsx onarımı hem de pdf onarım yazılım ürünleri. Daha fazla bilgi için ziyaret edin www.datanumen.com