วิธีการแตกไฟล์ซิป .Zip ไฟล์แนบโดยตรงใน Outlook ผ่าน VBA

เมื่อคุณได้รับไฟล์แนบใน “.zipหากคุณต้องการแตกไฟล์ที่มีนามสกุล ".zip" โดยทั่วไปแล้ว คุณควรบันทึกและแตกไฟล์ลงในไดรฟ์ภายในเครื่อง แต่หลายคนหวังที่จะแตกไฟล์โดยตรงใน Outlook บทความนี้จะสอนวิธีการทำเช่นนั้นผ่าน VBA

คุณคงเคยได้รับไฟล์แนบที่อยู่ใน “.zip” ไฟล์นามสกุล. เพื่อเข้าถึงไฟล์ภายในไฟล์เดียว zip คุณต้องแตกไฟล์ก่อน ในกรณีนี้ คุณต้องบันทึกไฟล์ก่อนตามปกติ zip แตกไฟล์ไปยังไดรฟ์ภายในเครื่อง จากนั้นคลิกขวาแล้วเลือก “แตกไฟล์ทั้งหมด” จากเมนูบริบท ในความเป็นจริง ผู้ใช้หลายคนชอบแตกไฟล์โดยตรงภายใน Outlook แต่ Outlook ไม่มีฟีเจอร์นั้นโดยตรง โชคดีที่คุณสามารถทำตามขั้นตอนต่อไปนี้เพื่อใช้ VBA ในการทำเช่นนั้นได้อย่างง่ายดาย

เปิดเครื่องรูดไฟล์ .Zip ไฟล์แนบโดยตรงใน Outlook

1. ในตอนแรกเปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นกดปุ่มลัด“ Alt + F11” ในหน้าต่าง Outlook เพื่อเข้าถึงตัวแก้ไข VBA
3. ถัดไปในหน้าต่าง“ Microsoft Visual Basic for Applications” เปิดโมดูลที่ไม่ได้ใช้งาน
4. จากนั้นคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโมดูลนี้

Public Sub UnzipFileInOutlook()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim strFileName As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
 
    'Save & Unzip the zip file in local drive
    Set objShell = CreateObject("Shell.Application")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyy-mm-dd-hh-mm-ss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.FileName
           objAttachment.SaveAsFile (strFilePath)
           objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strFilePath)).Items
        End If
    Next
 
    'Reattach the files extracted from the zip file
    strFileName = Dir(strTempFolder & "\")
 
    While Len(strFileName) > 0
          objMail.attachments.Add (strTempFolder & "\" & strFileName)
          strFileName = Dir
          objMail.Save
    Wend
 
    'Delete the attachments in “.zip” file extension
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           objAttachment.Delete
           objMail.Save
        End If
    Next
 
    'Delete the temp folder and files
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. หลังจากนั้นคุณสามารถเพิ่มโครงการ VBA ใหม่ลงในแถบเครื่องมือด่วนของหน้าต่างข้อความได้ตามปกติ
6. สุดท้ายคุณสามารถลอง

• ขั้นแรกให้เปิดข้อความด้วย zip ไฟล์ในหน้าต่างของตัวเอง
• จากนั้นคลิก“ การดำเนินการ”>“ แก้ไขข้อความ”
• จากนั้นคลิกปุ่มมาโครใหม่ในแถบเครื่องมือด่วน
• ในครั้งเดียวไฟล์ zip ไฟล์จะถูกคลายซิปออกมา ดังภาพหน้าจอต่อไปนี้:

กำจัดปัญหา PST ที่น่ารำคาญ

แม้ว่าไฟล์ PST ในรูปแบบ Unicode ใหม่จะรองรับขนาดไฟล์ 20 GB แต่ก็ยังควรที่จะทำให้ไฟล์มีขนาดเล็กที่สุด เป็นเพราะไฟล์ PST ขนาดใหญ่มีแนวโน้มที่จะเกิดความเสียหายได้ง่ายกว่ามาก เมื่อไฟล์ PST ของคุณถูกบุกรุกคุณจะต้องใช้ความพยายาม กู้คืน PST ข้อมูล. ในสถานการณ์นั้นคุณไม่มีทางเลือกอื่นนอกจากใช้เครื่องมือที่ได้รับการพิสูจน์แล้วและมีชื่อเสียงเช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ ซ่อม sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.