วิธีลบรายการ Outlook ที่ซ้ำกันอย่างรวดเร็วในโฟลเดอร์ผ่าน VBA

โซลูชัน Outlook September 29, 2025
แบ่งปันเลย:

หากคุณต้องการลบรายการที่ซ้ำกันใน Outlook การค้นหาและลบทีละรายการจะค่อนข้างยุ่งยาก บทความนี้จะสอนวิธีการลบรายการซ้ำอย่างรวดเร็วด้วย Outlook VBA

ในบทความก่อนหน้าของฉัน -“วิธีค้นหาและลบอีเมลที่ซ้ำกันอย่างรวดเร็วใน Outlook” คุณสามารถเรียนรู้เคล็ดลับในการค้นหาและลบอีเมลที่ซ้ำกันซึ่งในขั้นแรกจะจัดเรียงอีเมลตามหัวเรื่องจากนั้นตามเวลาที่ได้รับจากนั้นจึงแนบไฟล์แนบเพื่อค้นหารายการที่ซ้ำกันและสุดท้ายเลือกรายการที่ซ้ำกันแล้วกดปุ่ม“ ลบ” แม้ว่าวิธีนี้จะดูสะดวกกว่าเล็กน้อย แต่ก็มีปัญหามากกว่าเมื่อเทียบกับการใช้ Outlook VBA ด้วยรหัส VBA ต่อไปนี้คุณสามารถลบรายการที่ซ้ำกันได้อย่างรวดเร็วเพียงคลิกเดียวไม่ว่าจะเป็นอีเมลงานรายชื่อติดต่อหรือการนัดหมาย ตอนนี้อ่านเพื่อรับรหัสโดยละเอียด

ลบรายการ Outlook ที่ซ้ำกันอย่างรวดเร็วในโฟลเดอร์ผ่าน VBA

ลบรายการ Outlook ที่ซ้ำกันในโฟลเดอร์

  1. ขั้นแรก ให้เปิดโปรแกรม Outlook ของคุณ
  2. จากนั้นกดปุ่ม“ Alt + F11”
  3. ในหน้าต่างตัวแก้ไข VBA ที่ตามมาให้ดับเบิลคลิกเพื่อเปิดโมดูลที่ใช้งานอยู่หรือแทรกโมดูลใหม่โดยตรงโดย“ แทรก”>“ โมดูล”
  4. ถัดไปคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโมดูล
Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

รหัส VBA - ลบรายการ Outlook ที่ซ้ำกันในโฟลเดอร์อย่างรวดเร็ว

  1. หลังจากนั้นให้ลงชื่อแมโครนี้แบบดิจิทัลและเปลี่ยนระดับความปลอดภัยของแมโคร Outlook เป็นระดับต่ำ
  2. หลังจากนั้นคุณสามารถเรียกใช้โครงการ VBA ใหม่นี้ได้ คลิกโดยตรงที่ไอคอน“ Run” ในแถบเครื่องมือเรียกใช้แมโครนี้
  3. จากนั้นคุณจะต้องเลือกโฟลเดอร์ที่คุณต้องการลบรายการที่ซ้ำกันเลือกโฟลเดอร์
  4. สุดท้ายรายการที่ซ้ำกันในโฟลเดอร์ที่เลือกจะถูกลบพร้อมกัน

ปกป้องข้อมูล PST ที่มีช่องโหว่

เนื่องจากไฟล์ PST เสี่ยงต่อความเสียหายดังนั้นคุณควรใช้ความพยายามอย่างมากในการปกป้องไฟล์ PST ของคุณ ตัวอย่างเช่นคุณควรป้องกันไม่ให้ Outlook ถูกปิดอย่างไม่เหมาะสม นอกจากนี้คุณต้องเตรียมความพร้อม แก้ไข Outlook เครื่องมือเช่น DataNumen Outlook Repair ที่จะสามารถกอบกู้ PST ของคุณได้ทันเวลา

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้ SQL Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.

แบ่งปันเลย:

ความเห็นถูกปิด