วิธีพิมพ์ไฟล์แนบรูปภาพทั้งหมดของอีเมล Outlook อย่างรวดเร็วในหนึ่งหน้าเท่านั้น

เพื่อประหยัดหมึกพิมพ์และกระดาษ ผู้ใช้บางรายต้องการพิมพ์ภาพทั้งหมดที่แนบมาในอีเมลในหนึ่งหน้าเท่านั้น แทนที่จะพิมพ์หนึ่งภาพต่อหน้า ตอนนี้บทความนี้จะแบ่งปันวิธีการที่จะตระหนักถึงมัน

อย่างที่ทราบกันดีว่าการพิมพ์ภาพนั้นค่อนข้างเปลืองหมึกเครื่องพิมพ์ ดังนั้น เพื่อเป็นการประหยัดหมึกและกระดาษของเครื่องพิมพ์ คุณอาจต้องการพิมพ์ไฟล์แนบรูปภาพหลายไฟล์ในหน้าเดียวกัน แทนที่จะพิมพ์รูปภาพในหน้าแยกกัน แม้ว่า Outlook จะไม่มีฟีเจอร์ดังกล่าว แต่คุณก็ยังสามารถทำได้ด้วยวิธีต่อไปนี้

พิมพ์ไฟล์แนบรูปภาพทั้งหมดของอีเมล Outlook ในหน้าเดียวเท่านั้น

1. ขั้นแรก ให้เปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นในหน้าต่าง Outlook ให้แตะที่ปุ่ม "Alt + F11"
3. ถัดไป คุณจะเข้าสู่หน้าต่าง “Microsoft Visual Basic for Applications” ซึ่งในหน้าต่างนี้ คุณต้องเปิดใช้งาน “Microsoft Word Object Library” ก่อน
4. หลังจากนั้น คุณต้องเปิดโมดูลที่ไม่ได้ใช้งาน
5. จากนั้นคัดลอกและวางโค้ด VBA ต่อไปนี้ลงในโมดูลนี้

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. หลังจากนั้น คุณสามารถกลับไปที่รายการอีเมลได้ เลือกหรือเปิดอีเมลที่คุณต้องการพิมพ์ไฟล์แนบที่เป็นรูปภาพ
7. จากนั้น ทริกเกอร์มาโครนี้ ในหน้าต่างมาโครปัจจุบัน เพียงกดปุ่ม “F5” หรือคลิกไอคอน “เรียกใช้” ในแถบเครื่องมือ
8. สุดท้าย เมื่อมาโครทำงานเสร็จสิ้น ไฟล์แนบรูปภาพทั้งหมดของอีเมลต้นทางจะถูกพิมพ์ออกมาในหน้าเดียว เช่นเดียวกับภาพหน้าจอต่อไปนี้:

จัดการกับไฟล์ Outlook ที่เสียหาย

ด้วยข้อมูลที่เก็บไว้ใน Outlook ของคุณมากขึ้นเรื่อยๆ ไฟล์ Outlook ของคุณจึงมีความเสี่ยงเพิ่มมากขึ้น มันสามารถถูกบุกรุกได้เนื่องจากปัจจัยภายในและภายนอกต่างๆ นอกจากนี้ยังเป็นการยากที่จะคาดเดาความเสียหายของ Outlook ดังนั้น สิ่งที่คุณสามารถทำได้คือการประกันการช่วยเหลือทันทีและมีประสิทธิภาพเมื่อพบกับความเสียหายของ Outlook ตัวอย่างเช่น คุณต้องมีความชำนาญพิเศษ ซ่อม PST เครื่องมือเช่น DataNumen Outlook Repair ในบริเวณใกล้เคียง มันจะสแกนและกู้คืนไฟล์ที่เสียหายอย่างรวดเร็ว

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้ Sql Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.