วิธีแนบสไลด์เฉพาะของ a PowerPoint การนำเสนอไปยังอีเมล Outlook ของคุณ

โซลูชัน Outlook September 29, 2025

หากคุณต้องการแยกสไลด์เฉพาะของ PowerPoint นำเสนอไปยังงานนำเสนอใหม่ที่แยกจากกัน และแนบกับอีเมล Outlook คุณสามารถใช้วิธีที่แบ่งปันในบทความนี้

แทนที่จะแนบทั้งหมด PowerPoint งานนำเสนอไปยังอีเมล หากคุณต้องการแนบสไลด์เฉพาะของงานนำเสนอ โดยทั่วไป คุณต้องคัดลอกสไลด์ที่ต้องการไปยังงานนำเสนอใหม่ก่อน มันลำบากเกินไป ดังนั้น ในที่นี้ เราจะแสดงวิธีการที่สามารถดำเนินการได้ในครั้งเดียว

แนบสไลด์เฉพาะของ PowerPoint การนำเสนอไปยังอีเมล

ก่อนอื่นให้เปิดเฉพาะ PowerPoint การเสนอ
จากนั้นใน PowerPoint หน้าต่างแอปพลิเคชัน กดปุ่ม “Alt + F11” เพื่อเข้าสู่โปรแกรมแก้ไข VBA
ถัดไป ในหน้าต่างใหม่ ให้สร้างโมดูลใหม่โดยกด “แทรก” > “โมดูล”
จากนั้นคัดลอกและวางโค้ด VBA ต่อไปนี้ลงในโมดูลนี้

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

หลังจากนั้นคุณสามารถปิดหน้าต่างปัจจุบันได้
หลังจากนั้น ให้ไปที่ “ไฟล์” > “ตัวเลือก” > “แถบเครื่องมือด่วน” เพื่อเพิ่มมาโครใหม่ไปยังแถบเครื่องมือด่วน
สุดท้ายคุณสามารถลองใช้มาโครนี้ได้

ขั้นแรก ให้เลือกสไลด์เฉพาะที่คุณต้องการดึงข้อมูลออกมา
จากนั้นคลิกปุ่มมาโครในแถบเครื่องมือด่วน
ทันที อีเมล Outlook จะปรากฏขึ้นซึ่งมี PowerPoint งานนำเสนอที่ดึงมาจากงานนำเสนอต้นฉบับ

ใช้เครื่องมือการกู้คืนที่มีประสิทธิภาพ

อย่างที่เราทราบกันดีว่า Outlook มียูทิลิตี้ซ่อมแซมในตัว - scanpst. ถึงกระนั้นก็สามารถรับมือกับข้อบกพร่องเล็กน้อยใน Outlook ได้ หากสิ่งที่คุณเผชิญอยู่เป็นความเสียหายร้ายแรง มันจะไม่ส่งผลกระทบ เมื่อถึงจุดนั้น คุณไม่มีทางเลือกอื่นนอกจากต้องกลับมาใช้เครื่องมือซ่อมที่ทรงพลังและไว้วางใจได้อีกครั้ง เช่น DataNumen Outlook Repair. ด้วยวิธีนี้ คุณจะสามารถกู้คืนไฟล์ Outlook ที่เสียหายของคุณได้

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ mdf เสียหาย และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.