วิธีตั้งเวลาเตือนความจำที่แตกต่างกันโดยอัตโนมัติสำหรับการประชุม Outlook ในประเภทสีต่างๆ

หากคุณจัดประเภทการประชุม Outlook ตามประเภทสี และต้องการตั้งเวลาเตือนความจำที่แตกต่างกันสำหรับการประชุมในประเภทสีต่างๆ คุณสามารถอ้างอิงบทความนี้ได้ ที่นี่เราจะสอนให้คุณรู้ด้วย Outlook VBA

ตัวอย่างเช่น คุณกำลังแบ่งการประชุมออกเป็นสองกลุ่ม กลุ่มหนึ่งอยู่ในหมวดสี "นอกสถานที่" เนื่องจากสถานที่ประชุมอยู่ไกลเกินไป และอีกกลุ่มหนึ่งอยู่ในหมวดสี "ในสถานที่" เนื่องจากสถานที่ประชุมอยู่ใกล้ที่นี่ ตอนนี้ คุณต้องการให้ Outlook ตั้งเวลาเตือนอัตโนมัติสำหรับการประชุม "นอกสถานที่" เป็น 1 ชั่วโมงก่อนเริ่ม และการประชุม "ในสถานที่" เป็น 15 นาทีก่อนเริ่ม จากความต้องการนี้ เราจะมาแนะนำวิธีการง่ายๆ กัน

ตั้งค่าการเตือนที่แตกต่างกันโดยอัตโนมัติสำหรับการประชุมในประเภทสีต่างๆ

1. ในการเริ่มต้นให้เปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นกดปุ่ม "Alt + F11" เพื่อเข้าถึงหน้าต่างตัวแก้ไข VBA
3. ถัดไป ในหน้าต่างถัดไป ให้คัดลอกและวางโค้ด VBA ด้านล่างลงในโปรเจ็กต์ “ThisOutlookSession”

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. ต่อมา คุณต้องคลิกเข้าไปในซับรูทีน “Application_Startup” แล้วกดปุ่ม “F5” เพื่อเรียกใช้มาโครนี้
5. ตั้งแต่นั้นมา ทุกครั้งที่มีการเพิ่มการประชุมใหม่ลงในปฏิทินเริ่มต้นหรือคุณเปลี่ยนการประชุมที่มีอยู่ Outlook จะตรวจสอบประเภทของการประชุมโดยอัตโนมัติและตั้งเวลาเตือนความจำที่แตกต่างกันโดยอัตโนมัติ

กำจัดข้อผิดพลาดของ Outlook

Outlook อาจเกิดปัญหาต่างๆ ขึ้นได้เป็นครั้งคราว ดังนั้น การเรียนรู้วิธีรับมือกับปัญหาของ Outlook จึงเป็นสิ่งสำคัญอย่างยิ่ง เริ่มต้นด้วยการสำรองข้อมูล Outlook เป็นประจำ นอกจากนี้ หากมีงบประมาณเพียงพอ ขอแนะนำให้สำรองข้อมูลที่มีประสิทธิภาพสูงไว้ด้วย ซ่อมแซม Outlook เครื่องมือใกล้เคียงเช่น DataNumen Outlook Repair. สามารถสแกนไฟล์ PST ของคุณเพื่อหาปัญหาของ Outlook และแก้ไขได้อย่างง่ายดาย

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ การกู้คืน sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.