วิธีบันทึกจำนวนอีเมลที่เข้ามาโดยอัตโนมัติทุกวันในไฟล์ Excel

บทความนี้จะสอนวิธีให้ Outlook นับจำนวนอีเมลที่คุณได้รับทุกวันโดยอัตโนมัติและเขียนหมายเลขลงในไฟล์ Excel

ผู้ใช้จำนวนมากจะต้องนับจำนวนอีเมลทั้งหมดที่ได้รับในแต่ละวัน นอกจากนี้เพื่อการตรวจสอบที่สะดวกยิ่งขึ้นในอนาคตหลายคนคุ้นเคยกับการบันทึกจำนวนรวมลงในไฟล์ Excel ในกรณีนี้คุณสามารถเลือกที่จะนับและบันทึกด้วยตนเองได้ทุกวัน อย่างไรก็ตามมันค่อนข้างลำบาก และคุณอาจลืมทำบางครั้ง ดังนั้นคุณต้องต้องการวิธีการที่สะดวกซึ่งสามารถทำให้ Outlook ทำได้โดยอัตโนมัติ เพื่อตอบสนองต่อข้อกำหนดนี้เราจะสอนวิธีใช้ VBA เพื่อให้ทราบดังต่อไปนี้

บันทึกจำนวนอีเมลขาเข้าทั้งหมดโดยอัตโนมัติทุกวันในไฟล์ Excel

1. ในตอนแรกให้เปิดแอปพลิเคชัน Outlook ของคุณ
2. จากนั้นกดแป้นพิมพ์ลัด“ Alt + F11” ในหน้าต่างหลักของ Outlook
3. ถัดไปในหน้าต่างตัวแก้ไข VBA ป๊อปอัปเปิดโครงการ“ ThisOutlookSession”
4. จากนั้นคัดลอกและวางรหัส VBA ต่อไปนี้ลงในโครงการนี้

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. จากนั้นลงนามในรหัสนี้และเปลี่ยนการตั้งค่าแมโคร Outlook ของคุณเพื่ออนุญาตให้ใช้แมโครที่เซ็นชื่อ
6. หลังจากนั้นคุณต้องสร้างงานที่เกิดขึ้นประจำทุกวัน

• ขั้นแรกให้คลิกปุ่ม“ งานใหม่” ในบานหน้าต่างงาน
• ในหน้าต่างป๊อปอัปงานใหม่ให้คลิกปุ่ม "การเกิดซ้ำ"
• จากนั้นในกล่องโต้ตอบต่อมาให้เลือก“ รายวัน”“ ทุก 1 วัน” และ“ ไม่มีวันที่สิ้นสุด” และสุดท้ายกด“ ตกลง”
• ภายหลังเปลี่ยนหัวข้องานและการแจ้งเตือนตามความต้องการของคุณ
• ในที่สุดคลิกปุ่ม "บันทึกและปิด"

7. นับจากนี้เป็นต้นไปทุกครั้งที่มีการแจ้งเตือนการแจ้งเตือนของงานนี้ Outlook จะนับอีเมลที่ได้รับเมื่อวานโดยอัตโนมัติจากนั้นบันทึกหมายเลขลงในไฟล์ Excel ดังเช่นภาพหน้าจอต่อไปนี้:

หลีกหนีจากการสูญหายของข้อมูล PST อย่างถาวร

ไม่มีใครยินดีที่จะยอมรับการสูญเสียข้อมูล PST อย่างถาวร อย่างไรก็ตามไฟล์ Outlook PST มีแนวโน้มที่จะเกิดความเสียหาย ดังนั้นคุณควรระมัดระวังอย่างเพียงพอเช่นการสำรองข้อมูล PST ที่สม่ำเสมอและเป็นปัจจุบันและการรักษา การกู้คืน PST เครื่องมือในบริเวณใกล้เคียงเช่น DataNumen Outlook Repair.

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ ซ่อม sql และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.