Kako hitro odstraniti podvojene Outlookove elemente v mapi prek VBA

Če želite odstraniti podvojene elemente v Outlooku, bo iskanje in odstranjevanje enega za drugim precej težavno. Ta objava vas bo naučila, kako to hitro storiti z Outlook VBA.

V prejšnjem članku - "Kako hitro najti in odstraniti podvojena e-poštna sporočila v Outlooku«, se lahko naučite trika za iskanje in odstranjevanje podvojenih e-poštnih sporočil, ki najprej razvrstijo e-poštna sporočila po zadevi, nato po prejetem času in nato po priponkah, da najdete podvojene elemente in nazadnje izberete podvojene in pritisnete tipko »Izbriši«. Čeprav je ta metoda na videz nekoliko bolj priročna, je v primerjavi z uporabo Outlook VBA veliko bolj težavna. Z naslednjimi kodami VBA lahko preprosto z enim klikom hitro odstranite podvojene elemente, ne glede na e-pošto, opravila, stike ali sestanke. Zdaj preberite, če želite podrobneje spoznati kode.

Odstranite podvojene Outlookove elemente v mapi

1. Za začetek zaženite program Outlook.
2. Nato pritisnite tipki “Alt + F11”.
3. V naslednjem oknu urejevalnika VBA dvokliknite, da odprete modul, ki je v uporabi, ali neposredno vstavite nov modul z »Vstavi« > »Modul«.
4. Nato kopirajte in prilepite naslednje kode VBA v modul.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Nato digitalno podpišite ta makro in spremenite raven varnosti Outlookovega makra na nizko.
6. Pozneje lahko zaženete ta novi projekt VBA. Neposredno kliknite ikono »Zaženi« v orodni vrstici.
7. Nato boste morali izbrati mapo, v kateri želite odstraniti podvojene elemente.
8. Končno bodo podvojeni elementi v izbrani mapi takoj izbrisani.

Zaščitite ranljive podatke PST

Ker je datoteka PST dovzetna za poškodbe, bi morali vložiti veliko truda, da zaščitite datoteko PST. Na primer, preprečite nepravilno zaprtje Outlooka. Poleg tega morate pripraviti robustno Outlook popravek orodje, kot je DataNumen Outlook Repair ki bo lahko pravočasno rešil vaš PST.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z opomore SQL Server in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com