Kako hitro izvoziti Outlookovo mapo z vsemi podmapami in elementi v mapo Windows

Včasih boste morda želeli paketno izvoziti Outlookovo mapo z vsemi podmapami in elementi v mapo Windows. Ta članek vas bo naučil takšne metode, ki uporablja Outlook VBA.

Ko želite Outlookovo mapo izvoziti na lokalni pogon z vsemi elementi v isti strukturi mape, če izberete ročno shranjevanje in izvoz, vam bo vzelo veliko časa. Zakaj torej ne uporabite drugih sredstev, kot so orodja za izvoz ali kode VBA? Tukaj vam bomo razkrili tak del kode VBA. To vam bo omogočilo, da to dosežete kot bi mignil.

Izvozite vse podmape in elemente v Outlookovi mapi v mapo Windows

1. Na samem začetku zaženite program Outlook.
2. Nato v glavnem oknu programa Outlook pritisnite bližnjične tipke »Alt + F11«.
3. Nato se bo pojavilo okno »Microsoft Visual Basic for Applications«.
4. Nato morate odpreti prazen modul in vanj kopirati naslednje kode VBA.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Po tem morate zagotoviti, da vaš Outlook dovoljuje makre v nastavitvah makrov.
6. Sčasoma lahko poskusite.

• Najprej se vrnite v novo okno makra.
• Nato kliknite podprogram »ExportFolderWithAllItems«.
• Nato pritisnite tipko F5, da zaženete ta makro.
• Po tem morate izbrati določeno mapo.
• Nazadnje, ko prejmete sporočilo »Dokončano«, lahko dostopate do vnaprej določene lokalne mape. Videli boste, da so bili vsi elementi shranjeni v isti strukturi map.

Preprečite izgubo podatkov zaradi zrušitev Outlooka

Morda ste že kdaj naleteli na številne sesutja Outlooka. Večinoma bo Outlook po ponovnem zagonu deloval normalno. Vendar pa obstaja tudi možnost, da se naša datoteka PST poškoduje. Takrat boste poskušali čim bolje obnoviti svoje podatke PST, na primer z uporabo izkušenega orodja, kot je DataNumen Outlook Repair. To zmore popraviti Outlook napake in ekstrahirajte podatke iz ogrožene datoteke PST, ne da bi se pri tem zelo znojili.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z SQL Server popravilo in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com