Kako hitro izvoziti Outlookovo e-pošto kot slikovno datoteko

Nekateri uporabniki želijo Outlookovo e-pošto izvoziti kot slikovno datoteko, na primer datoteko jpg. Zato vam bomo v tem članku predstavili, kako ga pridobiti prek kode Outlook VBA.

Gotovo ste se naučili različnih trikov za izvoz e-pošte kot besedilne datoteke, Wordovega dokumenta itd. Kaj pa izvoz e-pošte kot slike, kot je datoteka JPG? Očitno Outlook nima te funkcije. Toda v nadaljevanju bomo z vami delili hitro sredstvo.

Hitro izvozite Outlookovo e-pošto kot slikovno datoteko

1. Za začetek zaženite aplikacijo Outlook.
2. Nato v glavnem Outlookovem oknu pridobite dostop do urejevalnika VBA v skladu s člankom – “Kako zagnati kodo VBA v Outlooku".
3. Nato omogočite »Knjižnica objektov MS Word« in »MS PowerPoint »Knjižnica objektov« s sklicevanjem na članek – »Kako dodati referenco knjižnice objektov v VBA".
4. Nato kopirajte in prilepite naslednjo kodo VBA v prazen modul.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Po tem morate dodati makro v orodno vrstico za hitri dostop.
6. Nato lahko zaprete urejevalnik VBA.
7. Pozneje izberite e-pošto in pritisnite gumb za makro v orodni vrstici za hitri dostop.
8. Ko se makro zaključi, lahko odprete vnaprej določeno lokalno mapo in poiščete izvoženo slikovno datoteko iz tega e-poštnega sporočila.

Pridobite Outlookove podatke iz poškodovane datoteke

Če je vaša Outlookova datoteka močno poškodovana, boste morda precej frustrirani. V tem primeru boste morali iz ogrožene datoteke izvleči Outlookove podatke. Nekateri uporabniki bodo običajno uporabili orodje za popravilo mape »Prejeto«. Vendar pa večinoma to ne bo prineslo nobenih rezultatov. Zato je bolje, da imate močan in zanesljiv vir. PST popravek orodje, kot je DataNumen Outlook Repair. Lahko skenira poškodovano datoteko in brez težav pridobi največ podatkov.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z mdf popravek in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com