Kako hitro izvoziti vse hiperpovezave v več Outlookovih e-poštnih sporočilih v Excel

Ko morate ekstrahirati vse hiperpovezave v enem ali več e-poštnih sporočilih, jih je neumno kopirati eno za drugo. Ta strost vas bo naučil metode za hiter izvoz vseh hiperpovezav v številnih e-poštnih sporočilih v Excel.

Zaradi nekaterih razlogov, kot je beleženje hiperpovezav v vseh vaših poslanih e-poštnih sporočilih, boste morali hiperpovezave ekstrahirati. Brez dvoma jih ni priporočljivo ročno ekstrahirati in kopirati. Morate hrepeneti po veliko pametnejšem pristopu, kot je uporaba VBA. Tukaj vam bomo delili tak del kode VBA, ki lahko izvozi vse hiperpovezave v številnih e-poštnih sporočilih v Excel s preprostim klikom.

Izvozi vse hiperpovezave v več e-poštnih sporočilih v Excel

1. Za starZaženite program Outlook kot običajno.
2. Nato morate v Outlookovem oknu pritisniti tipke »Alt + F11«.
3. Takoj boste dobili dostop do urejevalnika Outlook VBA.
4. Nato morate omogočiti »Microsoft Word Object Library« kot tudi »Microsoft Excel Object Library«. Kliknite »Orodja« > »Reference« in jih nato omogočite v pojavnem pogovornem oknu.
5. Nato morate odpreti neuporabljen modul, v katerem morate kopirati spodnjo kodo VBA v ta modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Po tem lahko zapustite trenutno okno urejevalnika VBA.
7. Pozneje odprite »Outlookove možnosti«, da prilagodite orodno vrstico za hitri dostop in dodate novo dodan makro v orodno vrstico za hitri dostop.
8. Končno lahko posnamete posnetek:

• Najprej na seznamu e-poštnih sporočil izberite e-poštna sporočila, katerih hiperpovezave želite ekstrahirati.
• Nato v orodni vrstici za hitri dostop kliknite gumb makra.
• Ko se makro konča, boste dobili Excelovo datoteko, kot je spodnja slika:

Odpravite nepričakovane težave z Outlookom

Težave z Outlookom se lahko občasno pojavijo brez kakršnih koli znamenj. Toda v smislu majhnih napak lahko Outlook obnovi s preprosto restart ali njen orodje za popravilo nabiralnika. Če pa naletite na resne težave, notranja sredstva ne bodo imela učinka. Na tej točki je vaša zadnja možnost zagotovo bolj ugledno in robustno orodje, kot je npr DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com