Kako hitro priložiti zadnjo spremenjeno datoteko v mapi Windows svojemu Outlookovemu e-poštnemu sporočilu

Včasih boste morda želeli hitro poiskati in priložiti nazadnje spremenjeno datoteko v določeni mapi Windows Outlookovemu e-poštnemu sporočilu. V tem primeru lahko uporabite metodo, predstavljeno v tem članku.

Nekateri uporabniki želijo, da Outlook hitro poišče in doda zadnjo spremenjeno datoteko v mapi sistema Windows e-poštnemu sporočilu, na primer nazadnje ustvarjeno, spremenjeno ali shranjeno datoteko. Vendar Outlook ne ponuja tako neposredne in izvorne funkcije. Zato bomo v nadaljevanju predstavili delček kode VBA, ki to lahko enostavno izvede.

E-pošti priložite zadnjo spremenjeno datoteko v mapi Windows

1. Na samem začetku bi morali zagnati aplikacijo Outlook.
2. Potem, ko pridete v glavno Outlookovo okno, lahko pritisnete tipke »Alt + F11«.
3. Nato boste uspešno dostopali do okna urejevalnika Outlook VBA.
4. Nato bi morali poiskati in odpreti modul, ki ni v uporabi.
5. Nato kopirajte in prilepite naslednjo kodo VBA v to okno modula.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Po tem lahko zapustite trenutno okno urejevalnika VBA in nadaljujete z dodajanjem novega makra v orodno vrstico za hitri dostop ali trak okna za sporočila.
7. Pozneje morate spremeniti raven varnosti makra v Outlooku na nizko.
8. Sčasoma lahko poskusite.

• Najprej ustvarite in sestavite novo Outlookovo e-poštno sporočilo kot običajno.
• Nato v orodni vrstici za hitri dostop pritisnite gumb za makro, kot je na spodnji sliki:
• Nato boste morali izbrati izvorno mapo Windows in pritisniti »V redu«.
• Če je taka datoteka v izbrani mapi Windows, boste prejeli poziv, podoben naslednjemu posnetku zaslona:
• Ko pritisnete »Da«, bo ta datoteka takoj priložena.

Čim prej rešite težave z Outlookom

Kadar koli naletite na težave z Outlookom, je priporočljivo, da jih rešite čim prej. V tej situaciji je bolje, da pripravite robusten Outlook popravek orodje vnaprej, kot npr DataNumen Outlook Repair. Sposoben je popraviti napake PST in učinkovito rešiti vaše Outlookove podatke.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com