Kako nastaviti različen privzeti čas opomnika za različne vrste označenih elementov v vašem Outlooku

Outlook bo privzeto samodejno uporabil privzeti čas opomnika za opravila za vse vrste označenih elementov. Če pa želite uporabiti drugačen čas opomnika za označene elemente glede na vrsto elementa, se lahko obrnete na metodo, predstavljeno v tem članku.

Outlook vam omogoča, da nastavite privzeti čas opomnika za vse označene elemente, ne glede na vrsto predmeta. Pojdite v meni »Datoteka« in kliknite »Možnosti«. Nato lahko v oknu »Outlookove možnosti« vidite možnost »Privzeti čas opomnika« na zavihku »Opravila«, kot je prikazano na naslednjem posnetku zaslona.

Kljub temu večina uporabnikov upa, da bodo za različne vrste označenih elementov uporabili različne čase opomnika, na primer »9:00« za označena e-poštna sporočila in »17:30« za označene stike. V nadaljevanju se bomo osredotočili na ta primer, da bi predstavili metodo.

Nastavite različen privzeti čas opomnika za različne vrste označenih elementov

1. Za začetek zaženite aplikacijo Outlook.
2. Nato odprite urejevalnik Outlook VBA s sklicevanjem na »Kako zagnati kodo VBA v Outlooku".
3. V naslednjem oknu »Microsoft Visual Basic for Applications« kopirajte naslednjo kodo v projekt »ThisOutlookSession«.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Po tem znova zaženite Outlook, da aktivirate ta makro.
5. Od zdaj naprej bo vsakič, ko e-poštno sporočilo označite z zastavico, čas opomnika nastavljen na »10:00« na rok za označitev.
6. In ko označite stik z zastavico, bo čas opomnika nastavljen na »17:30« na rok za označitev.

Prilagodljivo se lotite težav z Outlookom

V Outlooku lahko naletite na najrazličnejše težave. Zato se morate vnaprej naučiti nekaj ukrepov za njihovo reševanje. Če se na primer Outlook pogosto znova zažene, morate popraviti Office ali onemogočiti dodatke drugih ponudnikov itd. Če pa je vaša datoteka Outlook PST ogrožena, lahko najprej poskusite ... orodje za popravilo nabiralnika. Ko ne uspe, lahko še naprej uporabljate zmogljivo zunanje orodje, kot je DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z izterjava mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com