Kako samodejno uporabiti različne barve pisav za odgovarjanje in posredovanje e-pošte z Outlook VBA

Privzeto Outlooku ne morete dovoliti, da samodejno uporablja različne barve pisave za odgovarjanje in posredovanje e-poštnih sporočil. Če imate takšno zahtevo, si lahko preberete to objavo, da se naučite pametnega pristopa.

Outlook vam omogoča samo, da določite pisavo, ki se uporablja za odgovarjanje in posredovanje e-pošte. Odprite "Datoteka"> "Možnosti". Nato v razdelku »Outlook Options« odprite zavihek »Mail« in kliknite gumb »Pisalne potrebščine in pisave ...«. V naslednjem oknu lahko vidite gumb »Pisava« v razdelku »Odgovarjanje ali posredovanje sporočil«. Kliknite ga in nato lahko nastavite določeno barvo pisave za odgovarjanje in posredovanje e-pošte.

Vendar mnogi uporabniki upajo, da bodo za odgovor ali posredovanje e-pošte uporabili različne barve pisave. Čeprav Outlook za to ne ponuja neposrednih funkcij, ga je še vedno mogoče uresničiti s kodo VBA. Zdaj preberite, če želite dobiti takšen del kode VBA.

Samodejno uporabite različne barve pisav za odgovarjanje in posredovanje e-pošte

1. Za začetek zaženite aplikacijo Outlook.
2. Nato sprožite urejevalnik VBA s sklicevanjem na “Kako zagnati kodo VBA v Outlooku".
3. Nato v skladu z „Kako dodati referenco knjižnice objektov v VBA«, dodajte sklic na »Knjižnica objektov MS Word«.
4. Nato kopirajte naslednjo kodo v projekt “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Po tem znova zaženite Outlook, da aktivirate ta makro.
6. Končno lahko poskusite.

• Izberite ali odprite e-poštno sporočilo.
• Nato kliknite gumb »Odgovori«. V odgovoru na e-pošto lahko v besedo vnesete nekaj besed. Barva pisave mora biti roza.
• Ali pa kliknite gumb »Odgovori vsem«. V novo e-poštno sporočilo z odgovorom vnesite besede v telo. Barva pisave je zagotovo zelena.
• Podobno kliknite gumb »Naprej«. V pošiljki za posredovanje bodo nove besede prikazane modro.

Poiščite zanesljivo programsko opremo

V primeru Outlook korupcijaVečina uporabnikov se zateka k programski opremi za obnovitev Outlooka. Na trgu je na voljo veliko takšnih programov. Nekateri od njih so celo brezplačni. Kljub temu pa se morate paziti tistih iz neznanih virov, saj lahko stanje še poslabšajo. Pomagati si morate z zanesljivim in izkušenim orodjem, kot je DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z poškodovan sql in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com