Kako samodejno označiti sestanke ob koncu tedna kot zasebne v Outlooku

Oblikaost uporabniki so termini, ki so predvideni ob koncu tedna, običajno zasebni. Zato želijo, da Outlook samodejno označi in prikaže take sestanke kot zasebne. V tem članku bomo to uresničili z malo skriptiranja.

Da bi lažje razlikovali med poslovnimi in zasebnimi termini, Outlook uporabnikom omogoča, da termine označijo kot zasebne. Na ta način se vam zdi zelo priročno in enostavno tiskanje koledarja brez zasebnih sestankov. V tem primeru boste morda želeli, da vaš Outlook samodejno prepozna in označi določene sestanke kot zasebne. Na primer, na splošno so sestanki ob koncu tedna zasebni, zato želite, da jih Outlook samodejno označi kot zasebne. Nato vas bomo vodili, da to dosežete.

Samodejno označi sestanke ob koncu tedna kot zasebne

1. Najprej zaženite urejevalnik Outlook VBA v skladu z "Kako zagnati kodo VBA v Outlooku".
2. Nato v okno »Microsoft Visual Basic for Applications« vstavite naslednjo kodo v projekt »ThisOutlookSession«.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Po tem je restart Outlook za aktiviranje makra.
4. Od zdaj naprej bo Outlook vsakič, ko ustvarite nov sestanek ali spremenite obstoječega na konec tedna, samodejno označil kot zasebnega.

Rešite nadležne težave v Outlooku

Možno je, da ste pri delu z Outlookom naleteli na težave, kot so nepričakovana zamrznitev aplikacij, pojavna sporočila o napakah in tako naprej. Ko bi jih trpeli, bi bili zaskrbljeni. Prosim umiri se! Panika ne bo nič pomagala, le poslabšala bo zadevo. Najprej lahko preverite, ali lahko dostopate do datoteke PST kot običajno. Če je tako, morate popraviti datoteko PST, kar lahko storite prek orodje za popravilo nabiralnika ali močnejše zunanje orodje, npr DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z popravilo mdf in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com