Kako paketno izvoziti vsa e-poštna sporočila v pogovoru kot besedilne datoteke prek Outlooka VBA

Včasih boste morda želeli paketno zajeti vsa e-poštna sporočila v določenem pogovoru in jih nato paketno izvoziti v lokalno mapo kot besedilne datoteke. Ta članek vas bo naučil, kako ga hitro pridobiti.

Iz nekega razloga boste morda morali izvoziti vsa e-poštna sporočila v določenem pogovoru na lokalni pogon. Če to storite ročno, namreč iskanje in shranjevanje enega za drugim, bo to dolgočasno in naporno opravilo. Zato je bolje, da poiščete drugo hitrejšo metodo, kot je naslednja. Za pridobitev bo uporabil delček kode VBA, ne da bi se pri tem znojil.

Paketno izvozite vso pošto v pogovoru kot besedilne datoteke

1. Na začetku zaženite aplikacijo Outlook.
2. Nato pritisnite tipki “Alt + F11” za dostop do urejevalnika Outlook VBA.
3. Nato morate v novem oknu odpreti modul, ki ni v uporabi ali neposredno vstaviti nov modul.
4. Nato kopirajte in prilepite naslednje kode VBA v ta modul.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Po tem lahko dodate nov projekt VBA v orodno vrstico za hitri dostop kot običajno.
6. Pozneje zagotovite nizko raven varnosti makra Outlook.
7. Končno bi lahko poskusili.

• Najprej izberite e-poštno sporočilo.
• Nato v orodni vrstici za hitri dostop kliknite nov gumb makra.
• Ko prejmete sporočilo »Dokončano«, lahko odprete vnaprej določeno lokalno mapo, v kateri boste videli e-poštna sporočila v formatu »TXT«.

Nasveti za obnovitev podatkov PST po poškodbi

V Outlooku lahko pogosto naletite na različne Outlookove napake, od katerih so nekatere lahko izjemno resne, tako da neposredno vodijo do okvare PST. Takrat morate ukrepati popravilo PST datoteko, da poiščete svoje dragocene podatke. V tem primeru se lahko preprosto obrnete na ugledno in preizkušeno orodje, kot je DataNumen Outlook Repair.

Uvod avtorja:

Shirley Zhang je strokovnjakinja za obnovitev podatkov v DataNumen, Inc., ki je vodilna na svetu na področju tehnologij za obnovitev podatkov, vključno z opomore sql server in obeti za popravilo programskih izdelkov. Za več informacij obiščite www.datanumen.com